4 files changed, 54 insertions, 12 deletions
diff --git a/Completion/X/Command/_nedit b/Completion/X/Command/_nedit
index 75ca1bad4..8bf7cac43 100644
--- a/Completion/X/Command/_nedit
+++ b/Completion/X/Command/_nedit
@@ -1,4 +1,4 @@
-#compdef nedit nedit-nc=nc ncl=nc
+#compdef nedit nedit-nc=nc ncl=nc nedit-client=nc
 
 local state line expl nedit_common curcontext="$curcontext" ret=1
 typeset -A opt_args
diff --git a/Completion/X/Command/_papers b/Completion/X/Command/_papers
new file mode 100644
index 000000000..1c6076728
--- /dev/null
+++ b/Completion/X/Command/_papers
@@ -0,0 +1,18 @@
+#compdef papers
+
+_arguments -s -S : \
+  + '(help)' \
+  '(- : *)--version[display version information]' \
+  '(- : *)'{-h,--help}'[display help information]' \
+  '(- : *)--help-all[display all help information]' \
+  '(- : *)--help-gapplication[display help information for GApplication options]' \
+  + '(mode)' \
+  {-f,--fullscreen}'[run in fullscreen mode]' \
+  {-s,--presentation}'[run in presentation mode]' \
+  + '(page)' \
+  {-p,--page-label=}'[specify page label of document to display]:page label:' \
+  {-i,--page-index=}'[specify page number of document to display]:page index:' \
+  {-n,--named-dest=}'[specify named destination to display]:named destination:' \
+  + etc \
+  '--gapplication-service[enter GApplication service mode]' \
+  '*:document file:_files -g "*.(#i)(cb7|cbr|cbt|cbz|djv|djvu|pdf|tif|tiff)(-.)"'
diff --git a/Completion/X/Command/_pdftk b/Completion/X/Command/_pdftk
index b26deb15f..4029e52fe 100644
--- a/Completion/X/Command/_pdftk
+++ b/Completion/X/Command/_pdftk
@@ -6,8 +6,7 @@ _pdfwithhandle()
     _files "$@" -g '(#i)*.pdf'
 }
 
-local expl
-local -a opts operations
+local -a expl opts operations
 
 opts=(output encrypt_40bit encrypt_128bit allow owner_pw user_pw flatten
 	compress uncompress keep_first_id keep_final_id drop_xfa verbose
@@ -22,15 +21,13 @@ case $words[CURRENT-1] in
 	;;
 
     (allow)
-	#_description permissions expl "permission"
-	#compadd $expl \
 	_values -s , permission \
 	    Printing DegradedPrinting ModifyContents Assembly CopyContents \
 	    ScreenReaders ModifyAnnotations FillIn AllFeatures
 	;;
 
     (attach_files)
-	_files "$@"
+	_files
 	;;
 
     (fill_form)
@@ -51,11 +48,9 @@ case $words[CURRENT-1] in
 esac && return 0
 
 if [[ -n $words[(r)(${(j:|:)operations})] ]]; then
-    _description options expl "option"
-    compadd $@ $expl $opts
+  _wanted options expl "option" compadd -a opts
 else
-    _tags files operations
-    _alternative \
-	'files:PDF file:_pdfwithhandle' \
-	"operations:operation:($operations)"
+  _alternative \
+    'files:PDF file:_pdfwithhandle' \
+    "operations:operation:compadd -a operations"
 fi
diff --git a/Completion/X/Command/_sioyek b/Completion/X/Command/_sioyek
new file mode 100644
index 000000000..d9b15a953
--- /dev/null
+++ b/Completion/X/Command/_sioyek
@@ -0,0 +1,29 @@
+#compdef sioyek
+
+_arguments -S \
+  '--new-instance[create a new instance of sioyek when opening a file]' \
+  '--instance-name[select a specific sioyek instance by name]:name: ' \
+  '--new-window[open file in a new window within same instance]' \
+  '--reuse-window[force reuse of current window]' \
+  '--nofocus[do not bring instance to foreground]' \
+  '--version[print sioyek version]' \
+  '--page[which page to open]:page number: ' \
+  '--focus-text[set a visual mark on line including text]:text: ' \
+  '--focus-text-page[page to use for focus-text]:page number: ' \
+  '--inverse-search[command to execute for inverse search]:command: ' \
+  '--execute-command[command to execute on running instance]:command: ' \
+  '--execute-command-data[optional data for execute-command]:data: ' \
+  '--forward-search-file[forward search on file]:file:_files' \
+  '--forward-search-line[forward search on line]:line: ' \
+  '--forward-search-column[forward search on column]:column: ' \
+  '--zoom[set zoom level]:zoom level: ' \
+  '--xloc[set x position within page]:x-coordinate: ' \
+  '--yloc[set y position within page]:y-coordinate: ' \
+  '--window-id[apply command to specific window id]:window id: ' \
+  '--shared-database-path[path for shared bookmarks/highlights]:database path:_files' \
+  '--verbose[print extra information]' \
+  '--wait-for-response[wait for command to finish before returning]' \
+  '--no-auto-config[disable all config files except those next to executable]' \
+  '(-h --help)'{-h,--help}'[display help information]' \
+  '--help-all[display help including generic Qt options]' \
+  '*:pdf file:_files -g "*.pdf(-.)"'