runtime/queries/inko/highlights.scm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206

; Brackets and operators
[
  "("
  ")"
  "["
  "]"
  "{"
  "}"
] @punctuation.bracket

[
  ","
  "->"
  "."
  ":"
] @punctuation.delimiter

[
  "!="
  "%"
  "%="
  "&"
  "&="
  "*"
  "**"
  "**="
  "*="
  "+"
  "+="
  "-"
  "-="
  "/"
  "/="
  "<"
  "<<"
  "<<="
  "<="
  "=="
  ">"
  ">="
  ">>"
  ">>="
  ">>>"
  ">>>="
  "^"
  "^="
  "|"
  "|="
] @operator

; Keywords
[
  "as"
  "copy"
  "for"
  "impl"
  "in"
  "inline"
  "let"
  "move"
  "mut"
  "recover"
  "ref"
  "uni"
] @keyword

[
  "async"
  "await"
] @keyword.coroutine

"fn" @keyword.function

"import" @keyword.import

[
  "and"
  "or"
] @keyword.operator

[
  "trait"
  "type"
] @keyword.type

[
  "extern"
  (modifier)
  (visibility)
] @keyword.modifier

[
  "loop"
  "while"
  (break)
  (next)
] @keyword.repeat

"return" @keyword.return

[
  "throw"
  "try"
] @keyword.exception

[
  "case"
  "else"
  "if"
  "match"
] @keyword.conditional

; Identifiers/variable references
(identifier) @variable

; Comments
(line_comment) @comment @spell

; Literals
(self) @variable.builtin

(nil) @constant.builtin

[
  (true)
  (false)
] @boolean

(integer) @number

(float) @number.float

(string) @string

(escape_sequence) @string.escape

(interpolation
  "${" @punctuation.special
  "}" @punctuation.special) @none

(constant) @constant

; Patterns
(integer_pattern) @number

(string_pattern) @string

(constant_pattern) @constant

(boolean_pattern) @boolean

; Types
(generic_type
  name: _ @type)

(type) @type

; Imports
(extern_import
  path: _ @string)

(import
  (path
    (identifier) @module))

; Classes
(class
  name: _ @type)

(define_field
  name: _ @variable.member)

; Traits
(trait
  name: _ @type)

; Implementations
(implement_trait
  class: _ @type)

(reopen_class
  name: _ @type)

(bound
  name: _ @type)

; Methods
(method
  name: _ @function)

(external_function
  name: _ @function)

(argument
  name: _ @variable.parameter)

(named_argument
  name: _ @variable.parameter)

(call
  name: [
    (name)
    (constant)
  ] @function)

(field) @variable.member