summaryrefslogtreecommitdiffstats
path: root/queries/vimdoc/highlights.scm
blob: 78ae9dab919ffb543194ad1abff26f21bb39cb57 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
(h1) @text.title.1
(h2) @text.title.2
(h3) @text.title.3
(column_heading) @text.title.4
(column_heading
   "~" @conceal (#set! conceal ""))
(tag
   "*" @conceal (#set! conceal "")
   text: (_) @label)
(taglink
   "|" @conceal (#set! conceal "")
   text: (_) @text.reference)
(optionlink
   text: (_) @text.reference)
(codespan
   "`" @conceal (#set! conceal "")
   text: (_) @text.literal)
((codeblock) @text.literal.block (#set! "priority" 90))
(codeblock
   [">" (language)] @conceal (#set! conceal ""))
(block
   "<" @conceal (#set! conceal ""))
(argument) @parameter
(keycode) @string.special
(url) @text.uri
((note) @text.note
   (#any-of? @text.note "Note:" "NOTE:" "Notes:"))
((note) @text.warning
   (#any-of? @text.warning "Warning:" "WARNING:"))
((note) @text.danger
   (#any-of? @text.danger "Deprecated:" "DEPRECATED:"))