queries/python/locals.scm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137

; Program structure
(module) @local.scope

(class_definition
  body:
    (block
      (expression_statement
        (assignment
          left: (identifier) @local.definition.field)))) @local.scope

(class_definition
  body:
    (block
      (expression_statement
        (assignment
          left:
            (_
              (identifier) @local.definition.field))))) @local.scope

; Imports
(aliased_import
  alias: (identifier) @local.definition.import)

(import_statement
  name:
    (dotted_name
      ((identifier) @local.definition.import)))

(import_from_statement
  name:
    (dotted_name
      ((identifier) @local.definition.import)))

; Function with parameters, defines parameters
(parameters
  (identifier) @local.definition.parameter)

(default_parameter
  (identifier) @local.definition.parameter)

(typed_parameter
  (identifier) @local.definition.parameter)

(typed_default_parameter
  (identifier) @local.definition.parameter)

; *args parameter
(parameters
  (list_splat_pattern
    (identifier) @local.definition.parameter))

; **kwargs parameter
(parameters
  (dictionary_splat_pattern
    (identifier) @local.definition.parameter))

; Function defines function and scope
((function_definition
  name: (identifier) @local.definition.function) @local.scope
  (#set! definition.function.scope "parent"))

((class_definition
  name: (identifier) @local.definition.type) @local.scope
  (#set! definition.type.scope "parent"))

(class_definition
  body:
    (block
      (function_definition
        name: (identifier) @local.definition.method)))

; Loops
; not a scope!
(for_statement
  left:
    (pattern_list
      (identifier) @local.definition.var))

(for_statement
  left:
    (tuple_pattern
      (identifier) @local.definition.var))

(for_statement
  left: (identifier) @local.definition.var)

; not a scope!
;(while_statement) @local.scope
; for in list comprehension
(for_in_clause
  left: (identifier) @local.definition.var)

(for_in_clause
  left:
    (tuple_pattern
      (identifier) @local.definition.var))

(for_in_clause
  left:
    (pattern_list
      (identifier) @local.definition.var))

(dictionary_comprehension) @local.scope

(list_comprehension) @local.scope

(set_comprehension) @local.scope

; Assignments
(assignment
  left: (identifier) @local.definition.var)

(assignment
  left:
    (pattern_list
      (identifier) @local.definition.var))

(assignment
  left:
    (tuple_pattern
      (identifier) @local.definition.var))

(assignment
  left:
    (attribute
      (identifier)
      (identifier) @local.definition.field))

; Walrus operator  x := 1
(named_expression
  (identifier) @local.definition.var)

(as_pattern
  alias: (as_pattern_target) @local.definition.var)

; REFERENCES
(identifier) @local.reference