5 files changed, 92 insertions, 0 deletions
diff --git a/runtime/queries/turtle/folds.scm b/runtime/queries/turtle/folds.scm
new file mode 100644
index 000000000..f932a3731
--- /dev/null
+++ b/runtime/queries/turtle/folds.scm
@@ -0,0 +1,5 @@
+[
+  (directive)
+  (triple)
+  (blank_node_property_list)
+] @fold
diff --git a/runtime/queries/turtle/highlights.scm b/runtime/queries/turtle/highlights.scm
new file mode 100644
index 000000000..30d1f4513
--- /dev/null
+++ b/runtime/queries/turtle/highlights.scm
@@ -0,0 +1,62 @@
+(string) @string
+
+(lang_tag) @type
+
+[
+  "_:"
+  "<"
+  ">"
+  (namespace)
+] @module
+
+[
+  (iri_reference)
+  (prefixed_name)
+] @variable
+
+(blank_node_label) @variable
+
+"a" @variable.builtin
+
+(integer) @number
+
+[
+  (decimal)
+  (double)
+] @number.float
+
+(boolean_literal) @boolean
+
+[
+  "BASE"
+  "PREFIX"
+  "@prefix"
+  "@base"
+] @keyword
+
+[
+  "."
+  ","
+  ";"
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  (anon)
+] @punctuation.bracket
+
+(comment) @comment @spell
+
+(echar) @string.escape
+
+(rdf_literal
+  "^^" @type
+  datatype: (_
+    [
+      "<"
+      ">"
+      (namespace)
+    ] @type) @type)
diff --git a/runtime/queries/turtle/indents.scm b/runtime/queries/turtle/indents.scm
new file mode 100644
index 000000000..a60105667
--- /dev/null
+++ b/runtime/queries/turtle/indents.scm
@@ -0,0 +1,11 @@
+[
+  (directive)
+  (triple)
+  (blank_node_property_list)
+  (collection)
+] @indent.begin
+
+[
+  "]"
+  ")"
+] @indent.branch
diff --git a/runtime/queries/turtle/injections.scm b/runtime/queries/turtle/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/turtle/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/turtle/locals.scm b/runtime/queries/turtle/locals.scm
new file mode 100644
index 000000000..0e251e2fa
--- /dev/null
+++ b/runtime/queries/turtle/locals.scm
@@ -0,0 +1,12 @@
+(document) @local.scope
+
+(subject
+  [
+    (prefixed_name)
+    (iri_reference)
+  ] @local.definition.var)
+
+[
+  (prefixed_name)
+  (iri_reference)
+] @local.reference