4 files changed, 97 insertions, 0 deletions
diff --git a/runtime/queries/scss/folds.scm b/runtime/queries/scss/folds.scm
new file mode 100644
index 000000000..cbe41875e
--- /dev/null
+++ b/runtime/queries/scss/folds.scm
@@ -0,0 +1 @@
+; inherits: css
diff --git a/runtime/queries/scss/highlights.scm b/runtime/queries/scss/highlights.scm
new file mode 100644
index 000000000..726256f8e
--- /dev/null
+++ b/runtime/queries/scss/highlights.scm
@@ -0,0 +1,87 @@
+; inherits: css
+
+[
+  "@at-root"
+  "@debug"
+  "@error"
+  "@extend"
+  "@forward"
+  "@mixin"
+  "@use"
+  "@warn"
+] @keyword
+
+"@function" @keyword.function
+
+"@return" @keyword.return
+
+"@include" @keyword.import
+
+[
+  "@while"
+  "@each"
+  "@for"
+  "from"
+  "through"
+  "in"
+] @keyword.repeat
+
+(single_line_comment) @comment @spell
+
+(function_name) @function
+
+[
+  ">="
+  "<="
+] @operator
+
+(mixin_statement
+  (name) @function)
+
+(mixin_statement
+  (parameters
+    (parameter) @variable.parameter))
+
+(function_statement
+  (name) @function)
+
+(function_statement
+  (parameters
+    (parameter) @variable.parameter))
+
+(plain_value) @string
+
+(keyword_query) @function
+
+(identifier) @variable
+
+(variable_name) @variable
+
+(each_statement
+  (key) @variable.parameter)
+
+(each_statement
+  (value) @variable.parameter)
+
+(each_statement
+  (variable_value) @variable.parameter)
+
+(for_statement
+  (variable) @variable.parameter)
+
+(for_statement
+  (_
+    (variable_value) @variable.parameter))
+
+(argument) @variable.parameter
+
+(arguments
+  (variable_value) @variable.parameter)
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+(include_statement
+  (identifier) @function)
diff --git a/runtime/queries/scss/indents.scm b/runtime/queries/scss/indents.scm
new file mode 100644
index 000000000..3d54a0467
--- /dev/null
+++ b/runtime/queries/scss/indents.scm
@@ -0,0 +1,7 @@
+; inherits: css
+
+[
+  (mixin_statement)
+  (while_statement)
+  (each_statement)
+] @indent.begin
diff --git a/runtime/queries/scss/injections.scm b/runtime/queries/scss/injections.scm
new file mode 100644
index 000000000..c3a252a79
--- /dev/null
+++ b/runtime/queries/scss/injections.scm
@@ -0,0 +1,2 @@
+((single_line_comment) @injection.content
+  (#set! injection.language "comment"))