3 files changed, 65 insertions, 0 deletions
diff --git a/runtime/queries/gitattributes/highlights.scm b/runtime/queries/gitattributes/highlights.scm
new file mode 100644
index 000000000..aec7750f6
--- /dev/null
+++ b/runtime/queries/gitattributes/highlights.scm
@@ -0,0 +1,55 @@
+(dir_sep) @punctuation.delimiter
+
+(quoted_pattern
+  "\"" @punctuation.special)
+
+(range_notation) @string.special
+
+(range_notation
+  [
+    "["
+    "]"
+  ] @punctuation.bracket)
+
+(wildcard) @character.special
+
+(range_negation) @operator
+
+(character_class) @constant
+
+(class_range
+  "-" @operator)
+
+[
+  (ansi_c_escape)
+  (escaped_char)
+] @string.escape
+
+(attribute
+  (attr_name) @variable.parameter)
+
+(attribute
+  (builtin_attr) @variable.builtin)
+
+[
+  (attr_reset)
+  (attr_unset)
+  (attr_set)
+] @operator
+
+(boolean_value) @boolean
+
+(string_value) @string
+
+(macro_tag) @keyword.directive
+
+(macro_def
+  macro_name: (_) @property)
+
+; we do not lint syntax errors
+; [
+;   (pattern_negation)
+;   (redundant_escape)
+;   (trailing_slash)
+; ] @error
+(comment) @comment @spell
diff --git a/runtime/queries/gitattributes/injections.scm b/runtime/queries/gitattributes/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/gitattributes/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/gitattributes/locals.scm b/runtime/queries/gitattributes/locals.scm
new file mode 100644
index 000000000..2471b8bc6
--- /dev/null
+++ b/runtime/queries/gitattributes/locals.scm
@@ -0,0 +1,8 @@
+(macro_def
+  (attr_name) @local.definition.macro)
+
+(attribute
+  (attr_name) @local.reference)
+
+(attribute
+  (builtin_attr) @local.reference)