2 files changed, 80 insertions, 0 deletions
diff --git a/runtime/queries/dockerfile/highlights.scm b/runtime/queries/dockerfile/highlights.scm
new file mode 100644
index 000000000..72893f8b0
--- /dev/null
+++ b/runtime/queries/dockerfile/highlights.scm
@@ -0,0 +1,68 @@
+[
+  "FROM"
+  "AS"
+  "RUN"
+  "CMD"
+  "LABEL"
+  "EXPOSE"
+  "ENV"
+  "ADD"
+  "COPY"
+  "ENTRYPOINT"
+  "VOLUME"
+  "USER"
+  "WORKDIR"
+  "ARG"
+  "ONBUILD"
+  "STOPSIGNAL"
+  "HEALTHCHECK"
+  "SHELL"
+  "MAINTAINER"
+  "CROSS_BUILD"
+] @keyword
+
+[
+  ":"
+  "@"
+] @operator
+
+(comment) @comment @spell
+
+(image_spec
+  (image_tag
+    ":" @punctuation.special)
+  (image_digest
+    "@" @punctuation.special))
+
+(double_quoted_string) @string
+
+[
+  (heredoc_marker)
+  (heredoc_end)
+] @label
+
+((heredoc_block
+  (heredoc_line) @string)
+  (#set! priority 90))
+
+(expansion
+  [
+    "$"
+    "{"
+    "}"
+  ] @punctuation.special)
+
+((variable) @constant
+  (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+(arg_instruction
+  .
+  (unquoted_string) @property)
+
+(env_instruction
+  (env_pair
+    .
+    (unquoted_string) @property))
+
+(expose_instruction
+  (expose_port) @number)
diff --git a/runtime/queries/dockerfile/injections.scm b/runtime/queries/dockerfile/injections.scm
new file mode 100644
index 000000000..5d3bbffb7
--- /dev/null
+++ b/runtime/queries/dockerfile/injections.scm
@@ -0,0 +1,12 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((shell_command
+  (shell_fragment) @injection.content)
+  (#set! injection.language "bash")
+  (#set! injection.combined))
+
+((run_instruction
+  (heredoc_block) @injection.content)
+  (#set! injection.language "bash")
+  (#set! injection.include-children))