1 files changed, 39 insertions, 35 deletions
diff --git a/queries/toml/highlights.scm b/queries/toml/highlights.scm
index 1370f9121..f0a5177a7 100644
--- a/queries/toml/highlights.scm
+++ b/queries/toml/highlights.scm
@@ -1,54 +1,58 @@
-; Properties
-;-----------
-(bare_key) @type
+(table
+  [
+    (bare_key) @markup.heading
+    (dotted_key
+      (bare_key) @markup.heading)
+  ])
 
-(quoted_key) @string
+(table_array_element
+  [
+    (bare_key) @markup.heading
+    (dotted_key
+      (bare_key) @markup.heading)
+  ])
 
 (pair
-  (bare_key)) @property
+  [
+    (bare_key) @property
+    (dotted_key
+      (bare_key) @property)
+  ])
 
-(pair
-  (dotted_key
-    (bare_key) @property))
+[
+  (string)
+  (quoted_key)
+] @string
 
-; Literals
-;---------
 (boolean) @boolean
 
 (comment) @comment @spell
 
-(string) @string
-
 (escape_sequence) @string.escape
 
 (integer) @number
 
 (float) @number.float
 
-(offset_date_time) @string.special
-
-(local_date_time) @string.special
-
-(local_date) @string.special
-
-(local_time) @string.special
-
-; Punctuation
-;------------
-"." @punctuation.delimiter
-
-"," @punctuation.delimiter
+[
+  (local_date)
+  (local_date_time)
+  (local_time)
+  (offset_date_time)
+] @string.special
 
 "=" @operator
 
-"[" @punctuation.bracket
-
-"]" @punctuation.bracket
-
-"[[" @punctuation.bracket
-
-"]]" @punctuation.bracket
-
-"{" @punctuation.bracket
+[
+  "."
+  ","
+] @punctuation.delimiter
 
-"}" @punctuation.bracket
+[
+  "["
+  "]"
+  "[["
+  "]]"
+  "{"
+  "}"
+] @punctuation.bracket