feat!: drop modules, general refactor and cleanup

5 files changed, 161 insertions, 0 deletions

diff --git a/runtime/queries/rasi/folds.scm b/runtime/queries/rasi/folds.scm
new file mode 100644
index 000000000..2fd6c9fa7
--- /dev/null
+++ b/runtime/queries/rasi/folds.scm
@@ -0,0 +1,5 @@
+[
+  (rule_set)
+  (list_value)
+  (distance_calc)
+] @fold
diff --git a/runtime/queries/rasi/highlights.scm b/runtime/queries/rasi/highlights.scm
new file mode 100644
index 000000000..d095cef63
--- /dev/null
+++ b/runtime/queries/rasi/highlights.scm
@@ -0,0 +1,138 @@
+(comment) @comment @spell
+
+"@media" @keyword
+
+"@import" @keyword.import
+
+"@theme" @keyword.import
+
+(string_value) @string
+
+[
+  (integer_value)
+  (float_value)
+  "0"
+] @number
+
+(boolean_value) @boolean
+
+[
+  (feature_name)
+  (url_image_scale)
+  (direction)
+  (text_style_value)
+  (line_style_value)
+  (position_value)
+  (orientation_value)
+  (cursor_value)
+  "inherit"
+] @keyword
+
+(url_image
+  "url" @function.builtin)
+
+(gradient_image
+  "linear-gradient" @function.builtin)
+
+(distance_calc
+  "calc" @function.builtin)
+
+(rgb_color
+  [
+    "rgb"
+    "rgba"
+  ] @function.builtin)
+
+(hsl_color
+  [
+    "hsl"
+    "hsla"
+  ] @function.builtin)
+
+(hwb_color
+  [
+    "hwb"
+    "hwba"
+  ] @function.builtin)
+
+(cmyk_color
+  "cmyk" @function.builtin)
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+(distance_op) @operator
+
+[
+  ";"
+  ","
+  ":"
+  "."
+] @punctuation.delimiter
+
+[
+  (angle_unit)
+  (integer_distance_unit)
+  (float_distance_unit)
+] @string
+
+(percentage) @number
+
+(percentage
+  "%" @string)
+
+(global_selector) @character.special
+
+(id_selector) @constant
+
+(id_selector_view
+  [
+    "normal"
+    "selected"
+    "alternate"
+  ] @attribute)
+
+(id_selector_state
+  [
+    "normal"
+    "urgent"
+    "active"
+  ] @keyword.modifier)
+
+(hex_color) @number
+
+(hex_color
+  "#" @punctuation.special)
+
+(named_color
+  (identifier) @string.special)
+
+(named_color
+  "/" @operator)
+
+(reference_value
+  "@" @punctuation.special
+  (identifier) @variable)
+
+(reference_value
+  "var" @function.builtin
+  (identifier) @variable)
+
+(list_value
+  (identifier) @variable)
+
+(environ_value
+  "$" @punctuation.special
+  (identifier) @variable)
+
+(environ_value
+  "env" @function.builtin
+  (identifier) @variable)
+
+(property_name) @property
diff --git a/runtime/queries/rasi/indents.scm b/runtime/queries/rasi/indents.scm
new file mode 100644
index 000000000..849d8aeac
--- /dev/null
+++ b/runtime/queries/rasi/indents.scm
@@ -0,0 +1,6 @@
+(rule_set) @indent.begin
+
+(block
+  "}" @indent.branch)
+
+(comment) @indent.ignore
diff --git a/runtime/queries/rasi/injections.scm b/runtime/queries/rasi/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/rasi/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/rasi/locals.scm b/runtime/queries/rasi/locals.scm
new file mode 100644
index 000000000..9210de6ea
--- /dev/null
+++ b/runtime/queries/rasi/locals.scm
@@ -0,0 +1,10 @@
+(rule_set
+  (selectors
+    (id_selector))) @local.scope
+
+(block
+  (declaration
+    (property_name) @local.definition.var))
+
+(reference_value
+  name: (identifier) @local.reference)