feat!: drop modules, general refactor and cleanup

4 files changed, 205 insertions, 0 deletions

diff --git a/runtime/queries/r/highlights.scm b/runtime/queries/r/highlights.scm
new file mode 100644
index 000000000..c849dd838
--- /dev/null
+++ b/runtime/queries/r/highlights.scm
@@ -0,0 +1,148 @@
+; Literals
+(integer) @number
+
+(float) @number.float
+
+(complex) @number
+
+(string) @string
+
+(string
+  (string_content
+    (escape_sequence) @string.escape))
+
+; Comments
+(comment) @comment @spell
+
+((program
+  .
+  (comment) @keyword.directive @nospell)
+  (#lua-match? @keyword.directive "^#!/"))
+
+; Operators
+[
+  "?"
+  ":="
+  "="
+  "<-"
+  "<<-"
+  "->"
+  "->>"
+  "~"
+  "|>"
+  "||"
+  "|"
+  "&&"
+  "&"
+  "<"
+  "<="
+  ">"
+  ">="
+  "=="
+  "!="
+  "+"
+  "-"
+  "*"
+  "/"
+  "::"
+  ":::"
+  "**"
+  "^"
+  "$"
+  "@"
+  ":"
+  "!"
+  "special"
+] @operator
+
+; Punctuation
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+  "[["
+  "]]"
+] @punctuation.bracket
+
+(comma) @punctuation.delimiter
+
+; Variables
+(identifier) @variable
+
+; Functions
+(binary_operator
+  lhs: (identifier) @function
+  operator: "<-"
+  rhs: (function_definition))
+
+(binary_operator
+  lhs: (identifier) @function
+  operator: "="
+  rhs: (function_definition))
+
+; Calls
+(call
+  function: (identifier) @function.call)
+
+(extract_operator
+  rhs: (identifier) @variable.member)
+
+function: (extract_operator
+  rhs: (identifier) @function.method.call)
+
+; Parameters
+(parameters
+  (parameter
+    name: (identifier) @variable.parameter))
+
+(arguments
+  (argument
+    name: (identifier) @variable.parameter))
+
+; Namespace
+(namespace_operator
+  lhs: (identifier) @module)
+
+(call
+  function: (namespace_operator
+    rhs: (identifier) @function))
+
+; Keywords
+(function_definition
+  name: "function" @keyword.function)
+
+(function_definition
+  name: "\\" @operator)
+
+(return) @keyword.return
+
+[
+  "if"
+  "else"
+] @keyword.conditional
+
+[
+  "while"
+  "repeat"
+  "for"
+  "in"
+  (break)
+  (next)
+] @keyword.repeat
+
+[
+  (true)
+  (false)
+] @boolean
+
+[
+  (null)
+  (inf)
+  (nan)
+  (na)
+  (dots)
+  (dot_dot_i)
+] @constant.builtin
diff --git a/runtime/queries/r/indents.scm b/runtime/queries/r/indents.scm
new file mode 100644
index 000000000..79dbe5167
--- /dev/null
+++ b/runtime/queries/r/indents.scm
@@ -0,0 +1,33 @@
+[
+  (braced_expression)
+  (parenthesized_expression)
+  (call)
+  "if"
+  "else"
+  "while"
+  "repeat"
+  "for"
+] @indent.begin
+
+(binary_operator
+  rhs: (_) @_no_indent
+  (#not-kind-eq? @_no_indent function_definition)) @indent.begin
+
+[
+  "}"
+  ")"
+] @indent.branch
+
+((parameters
+  .
+  (parameter
+    name: (identifier))) @indent.align
+  (#set! indent.open_delimiter "(")
+  (#set! indent.close_delimiter ")"))
+
+[
+  ")"
+  "}"
+] @indent.end
+
+(comment) @indent.ignore
diff --git a/runtime/queries/r/injections.scm b/runtime/queries/r/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/r/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/r/locals.scm b/runtime/queries/r/locals.scm
new file mode 100644
index 000000000..3377552c8
--- /dev/null
+++ b/runtime/queries/r/locals.scm
@@ -0,0 +1,22 @@
+; locals.scm
+(function_definition) @local.scope
+
+(argument
+  name: (identifier) @local.definition)
+
+(parameter
+  name: (identifier) @local.definition)
+
+(binary_operator
+  lhs: (identifier) @local.definition
+  operator: "<-")
+
+(binary_operator
+  lhs: (identifier) @local.definition
+  operator: "=")
+
+(binary_operator
+  operator: "->"
+  rhs: (identifier) @local.definition)
+
+(identifier) @local.reference