feat!: drop modules, general refactor and cleanup

4 files changed, 109 insertions, 0 deletions

diff --git a/runtime/queries/ninja/folds.scm b/runtime/queries/ninja/folds.scm
new file mode 100644
index 000000000..341a8b8c1
--- /dev/null
+++ b/runtime/queries/ninja/folds.scm
@@ -0,0 +1 @@
+(body) @fold
diff --git a/runtime/queries/ninja/highlights.scm b/runtime/queries/ninja/highlights.scm
new file mode 100644
index 000000000..8323ee9e9
--- /dev/null
+++ b/runtime/queries/ninja/highlights.scm
@@ -0,0 +1,101 @@
+[
+  "default"
+  "pool"
+  "rule"
+  "build"
+] @keyword
+
+[
+  "include"
+  "subninja"
+] @keyword.import
+
+":" @punctuation.delimiter
+
+[
+  "="
+  "|"
+  "||"
+  "|@"
+] @operator
+
+[
+  "$"
+  "{"
+  "}"
+] @punctuation.special
+
+;
+; Names
+; =====
+(pool
+  name: (identifier) @type)
+
+(rule
+  name: (identifier) @function)
+
+(let
+  name: (identifier) @constant)
+
+(expansion
+  (identifier) @constant)
+
+(build
+  rule: (identifier) @function)
+
+;
+; Paths and Text
+; ==============
+(path) @string.special.path
+
+(text) @string
+
+;
+; Builtins
+; ========
+(pool
+  name: (identifier) @type.builtin
+  (#any-of? @type.builtin "console"))
+
+(build
+  rule: (identifier) @function.builtin
+  (#any-of? @function.builtin "phony" "dyndep"))
+
+; Top level bindings
+; ------------------
+(manifest
+  (let
+    name: ((identifier) @constant.builtin
+      (#any-of? @constant.builtin "builddir" "ninja_required_version"))))
+
+; Rules bindings
+; -----------------
+(rule
+  (body
+    (let
+      name: (identifier) @constant.builtin
+      (#not-any-of? @constant.builtin
+        "command" "depfile" "deps" "msvc_deps_prefix" "description" "dyndep" "generator" "in"
+        "in_newline" "out" "restat" "rspfile" "rspfile_content" "pool"))))
+
+;
+; Expansion
+; ---------
+(expansion
+  (identifier) @constant.macro
+  (#any-of? @constant.macro "in" "out"))
+
+;
+; Escape sequences
+; ================
+(quote) @string.escape
+
+;
+; Others
+; ======
+[
+  (split)
+  (comment)
+] @comment
+
+(comment) @spell
diff --git a/runtime/queries/ninja/indents.scm b/runtime/queries/ninja/indents.scm
new file mode 100644
index 000000000..80344cdfb
--- /dev/null
+++ b/runtime/queries/ninja/indents.scm
@@ -0,0 +1,5 @@
+[
+  (pool)
+  (rule)
+  (build)
+] @indent.begin
diff --git a/runtime/queries/ninja/injections.scm b/runtime/queries/ninja/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/ninja/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))