feat!: drop modules, general refactor and cleanup

4 files changed, 190 insertions, 0 deletions

diff --git a/runtime/queries/jsx/folds.scm b/runtime/queries/jsx/folds.scm
new file mode 100644
index 000000000..93c3d9c8c
--- /dev/null
+++ b/runtime/queries/jsx/folds.scm
@@ -0,0 +1 @@
+(jsx_element) @fold
diff --git a/runtime/queries/jsx/highlights.scm b/runtime/queries/jsx/highlights.scm
new file mode 100644
index 000000000..0615d253a
--- /dev/null
+++ b/runtime/queries/jsx/highlights.scm
@@ -0,0 +1,157 @@
+(jsx_element
+  open_tag: (jsx_opening_element
+    [
+      "<"
+      ">"
+    ] @tag.delimiter))
+
+(jsx_element
+  close_tag: (jsx_closing_element
+    [
+      "</"
+      ">"
+    ] @tag.delimiter))
+
+(jsx_self_closing_element
+  [
+    "<"
+    "/>"
+  ] @tag.delimiter)
+
+(jsx_attribute
+  (property_identifier) @tag.attribute)
+
+(jsx_opening_element
+  name: (identifier) @tag.builtin)
+
+(jsx_closing_element
+  name: (identifier) @tag.builtin)
+
+(jsx_self_closing_element
+  name: (identifier) @tag.builtin)
+
+(jsx_opening_element
+  ((identifier) @tag
+    (#lua-match? @tag "^[A-Z]")))
+
+; Handle the dot operator effectively - <My.Component>
+(jsx_opening_element
+  (member_expression
+    (identifier) @tag.builtin
+    (property_identifier) @tag))
+
+(jsx_closing_element
+  ((identifier) @tag
+    (#lua-match? @tag "^[A-Z]")))
+
+; Handle the dot operator effectively - </My.Component>
+(jsx_closing_element
+  (member_expression
+    (identifier) @tag.builtin
+    (property_identifier) @tag))
+
+(jsx_self_closing_element
+  ((identifier) @tag
+    (#lua-match? @tag "^[A-Z]")))
+
+; Handle the dot operator effectively - <My.Component />
+(jsx_self_closing_element
+  (member_expression
+    (identifier) @tag.builtin
+    (property_identifier) @tag))
+
+(html_character_reference) @tag
+
+(jsx_text) @none @spell
+
+(html_character_reference) @character.special
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading)
+  (#eq? @_tag "title"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading.1)
+  (#eq? @_tag "h1"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading.2)
+  (#eq? @_tag "h2"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading.3)
+  (#eq? @_tag "h3"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading.4)
+  (#eq? @_tag "h4"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading.5)
+  (#eq? @_tag "h5"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.heading.6)
+  (#eq? @_tag "h6"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.strong)
+  (#any-of? @_tag "strong" "b"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.italic)
+  (#any-of? @_tag "em" "i"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.strikethrough)
+  (#any-of? @_tag "s" "del"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.underline)
+  (#eq? @_tag "u"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.raw)
+  (#any-of? @_tag "code" "kbd"))
+
+((jsx_element
+  (jsx_opening_element
+    name: (identifier) @_tag)
+  (jsx_text) @markup.link.label)
+  (#eq? @_tag "a"))
+
+((jsx_attribute
+  (property_identifier) @_attr
+  (string
+    (string_fragment) @string.special.url))
+  (#any-of? @_attr "href" "src"))
+
+((jsx_element) @_jsx_element
+  (#set! @_jsx_element bo.commentstring "{/* %s */}"))
+
+((jsx_attribute) @_jsx_attribute
+  (#set! @_jsx_attribute bo.commentstring "// %s"))
diff --git a/runtime/queries/jsx/indents.scm b/runtime/queries/jsx/indents.scm
new file mode 100644
index 000000000..812bc255d
--- /dev/null
+++ b/runtime/queries/jsx/indents.scm
@@ -0,0 +1,21 @@
+[
+  (jsx_element)
+  (jsx_self_closing_element)
+  (jsx_expression)
+] @indent.begin
+
+(jsx_closing_element
+  ">" @indent.end)
+
+(jsx_self_closing_element
+  "/>" @indent.end)
+
+[
+  (jsx_closing_element)
+  ">"
+] @indent.branch
+
+; <button
+; />
+(jsx_self_closing_element
+  "/>" @indent.branch)
diff --git a/runtime/queries/jsx/injections.scm b/runtime/queries/jsx/injections.scm
new file mode 100644
index 000000000..269ee3fff
--- /dev/null
+++ b/runtime/queries/jsx/injections.scm
@@ -0,0 +1,11 @@
+; Styled Jsx <style jsx>
+(jsx_element
+  (jsx_opening_element
+    (identifier) @_name
+    (#eq? @_name "style")
+    (jsx_attribute) @_attr
+    (#eq? @_attr "jsx"))
+  (jsx_expression
+    ((template_string) @injection.content
+      (#set! injection.language "css"))
+    (#offset! @injection.content 0 1 0 -1)))