feat!: drop modules, general refactor and cleanup

5 files changed, 190 insertions, 0 deletions

diff --git a/runtime/queries/fusion/folds.scm b/runtime/queries/fusion/folds.scm
new file mode 100644
index 000000000..179fc160b
--- /dev/null
+++ b/runtime/queries/fusion/folds.scm
@@ -0,0 +1,6 @@
+[
+  (comment)
+  (block)
+  (afx_comment)
+  (afx_element)
+] @fold
diff --git a/runtime/queries/fusion/highlights.scm b/runtime/queries/fusion/highlights.scm
new file mode 100644
index 000000000..7108e5705
--- /dev/null
+++ b/runtime/queries/fusion/highlights.scm
@@ -0,0 +1,132 @@
+(comment) @comment @spell
+
+(afx_comment) @comment @spell
+
+; identifiers afx
+(afx_opening_element
+  (afx_identifier) @tag)
+
+(afx_closing_element
+  (afx_identifier) @tag)
+
+(afx_element_self_closing
+  (afx_identifier) @tag)
+
+(afx_attribute
+  (afx_property_identifier) @tag.attribute)
+
+(afx_text) @spell
+
+; identifiers eel
+(eel_object_path
+  (eel_path_identifier) @variable.builtin
+  (#any-of? @variable.builtin "this" "props"))
+
+(eel_object_path
+  (eel_path_identifier) @variable)
+
+(eel_object_pair
+  key: (eel_property_name) @property)
+
+(eel_method_name) @function
+
+(eel_parameter) @variable
+
+; identifiers fusion
+; -----------
+(path_part) @property
+
+(meta_property) @attribute
+
+(prototype_signature
+  "prototype" @keyword)
+
+(include_statement
+  "include" @keyword.import
+  (source_file) @string.special.url)
+
+(namespace_declaration
+  "namespace" @keyword.type
+  (alias_namespace) @module)
+
+(type
+  name: (type_name) @type)
+
+; tokens
+; ------
+(afx_opening_element
+  [
+    "<"
+    ">"
+  ] @punctuation.bracket)
+
+(afx_closing_element
+  [
+    "<"
+    ">"
+    "/"
+  ] @punctuation.bracket)
+
+(afx_element_self_closing
+  [
+    "<"
+    "/>"
+  ] @punctuation.bracket)
+
+[
+  (package_name)
+  (alias_namespace)
+] @module
+
+(namespace_declaration
+  "=" @operator)
+
+(assignment
+  "=" @operator)
+
+(copy
+  "<" @operator)
+
+(deletion) @operator
+
+(eel_binary_expression
+  operator: _ @operator)
+
+(eel_not_expression
+  [
+    "!"
+    "not"
+  ] @operator)
+
+(string) @string
+
+(number) @number
+
+(boolean) @boolean
+
+(null) @constant.builtin
+
+(value_expression
+  start: _ @punctuation.special
+  end: _ @punctuation.special)
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ":"
+  "."
+  "?"
+] @punctuation.delimiter
+
+(eel_ternary_expression
+  [
+    "?"
+    ":"
+  ] @keyword.conditional.ternary)
diff --git a/runtime/queries/fusion/indents.scm b/runtime/queries/fusion/indents.scm
new file mode 100644
index 000000000..0ba6cf758
--- /dev/null
+++ b/runtime/queries/fusion/indents.scm
@@ -0,0 +1,24 @@
+[
+  (block)
+  (value_dsl)
+  (afx_element)
+  (afx_element_self_closing)
+  (eel_array)
+  (eel_object)
+] @indent.begin
+
+(block
+  end: _ @indent.branch)
+
+(value_dsl
+  end: _ @indent.branch)
+
+(eel_array
+  end: _ @indent.branch)
+
+(eel_object
+  end: _ @indent.branch)
+
+(afx_closing_element) @indent.branch
+
+(comment) @indent.ignore
diff --git a/runtime/queries/fusion/injections.scm b/runtime/queries/fusion/injections.scm
new file mode 100644
index 000000000..085cdb458
--- /dev/null
+++ b/runtime/queries/fusion/injections.scm
@@ -0,0 +1,5 @@
+([
+  (comment)
+  (afx_comment)
+] @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/fusion/locals.scm b/runtime/queries/fusion/locals.scm
new file mode 100644
index 000000000..d23e0ab46
--- /dev/null
+++ b/runtime/queries/fusion/locals.scm
@@ -0,0 +1,23 @@
+; Fusion base
+(block) @local.scope
+
+(namespace_declaration
+  (alias_namespace) @local.definition.namespace)
+
+(property
+  (path
+    (path_part) @local.definition.field))
+
+(type
+  namespace: (package_name)? @local.definition.namespace
+  name: (type_name) @local.definition.type)
+
+; Eel Expressions
+(eel_arrow_function) @local.scope
+
+(eel_object) @local.scope
+
+(eel_parameter) @local.definition.parameter
+
+(eel_object_pair
+  key: (eel_property_name) @local.definition.field)