feat!: drop modules, general refactor and cleanup

5 files changed, 263 insertions, 0 deletions

diff --git a/runtime/queries/firrtl/folds.scm b/runtime/queries/firrtl/folds.scm
new file mode 100644
index 000000000..4c64e644f
--- /dev/null
+++ b/runtime/queries/firrtl/folds.scm
@@ -0,0 +1,6 @@
+[
+  (circuit)
+  (module)
+  (when)
+  (else)
+] @fold
diff --git a/runtime/queries/firrtl/highlights.scm b/runtime/queries/firrtl/highlights.scm
new file mode 100644
index 000000000..0a90fa55b
--- /dev/null
+++ b/runtime/queries/firrtl/highlights.scm
@@ -0,0 +1,198 @@
+; Namespaces
+(circuit
+  (identifier) @module)
+
+(module
+  (identifier) @module)
+
+; Types
+((identifier) @type
+  (#lua-match? @type "^[A-Z][A-Za-z0-9_$]*$"))
+
+; Keywords
+[
+  "circuit"
+  "module"
+  "extmodule"
+  "flip"
+  "parameter"
+  "reset"
+  "wire"
+  "cmem"
+  "smem"
+  "mem"
+  "reg"
+  "with"
+  "mport"
+  "inst"
+  "of"
+  "node"
+  "is"
+  "invalid"
+  "skip"
+  "infer"
+  "read"
+  "write"
+  "rdwr"
+  "defname"
+] @keyword
+
+; Qualifiers
+(qualifier) @keyword.modifier
+
+; Storageclasses
+[
+  "input"
+  "output"
+] @keyword.modifier
+
+; Conditionals
+[
+  "when"
+  "else"
+] @keyword.conditional
+
+; Annotations
+(info) @attribute
+
+; Builtins
+[
+  "stop"
+  "printf"
+  "assert"
+  "assume"
+  "cover"
+  "attach"
+  "mux"
+  "validif"
+] @function.builtin
+
+[
+  "UInt"
+  "SInt"
+  "Analog"
+  "Fixed"
+  "Clock"
+  "AsyncReset"
+  "Reset"
+] @type.builtin
+
+; Fields
+[
+  "data-type"
+  "depth"
+  "read-latency"
+  "write-latency"
+  "read-under-write"
+  "reader"
+  "writer"
+  "readwriter"
+] @variable.member
+
+((field_id) @variable.member
+  (#set! priority 105))
+
+(port
+  (identifier) @variable.member)
+
+(wire
+  (identifier) @variable.member)
+
+(cmem
+  (identifier) @variable.member)
+
+(smem
+  (identifier) @variable.member)
+
+(memory
+  (identifier) @variable.member)
+
+(register
+  (identifier) @variable.member)
+
+; Parameters
+(primitive_operation
+  (identifier) @variable.parameter)
+
+(mux
+  (identifier) @variable.parameter)
+
+(printf
+  (identifier) @variable.parameter)
+
+(reset
+  (identifier) @variable.parameter)
+
+(stop
+  (identifier) @variable.parameter)
+
+; Variables
+(identifier) @variable
+
+; Operators
+(primop) @keyword.operator
+
+[
+  "+"
+  "-"
+  "="
+  "=>"
+  "<="
+  "<-"
+] @operator
+
+; Literals
+[
+  (uint)
+  (number)
+] @number
+
+(number_str) @string.special
+
+(double) @number.float
+
+(string) @string
+
+(escape_sequence) @string.escape
+
+[
+  "old"
+  "new"
+  "undefined"
+] @constant.builtin
+
+; Punctuation
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  "<"
+  ">"
+] @punctuation.bracket
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+[
+  ","
+  "."
+  ":"
+] @punctuation.delimiter
+
+; Comments
+(comment) @comment @spell
+
+[
+  "=>"
+  "<="
+  "="
+] @operator
diff --git a/runtime/queries/firrtl/indents.scm b/runtime/queries/firrtl/indents.scm
new file mode 100644
index 000000000..e172e1e81
--- /dev/null
+++ b/runtime/queries/firrtl/indents.scm
@@ -0,0 +1,12 @@
+[
+  (circuit)
+  (module)
+  (memory)
+  (when)
+  (else)
+] @indent.begin
+
+[
+  (ERROR)
+  (comment)
+] @indent.auto
diff --git a/runtime/queries/firrtl/injections.scm b/runtime/queries/firrtl/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/firrtl/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/firrtl/locals.scm b/runtime/queries/firrtl/locals.scm
new file mode 100644
index 000000000..97b7931bf
--- /dev/null
+++ b/runtime/queries/firrtl/locals.scm
@@ -0,0 +1,45 @@
+; Scopes
+[
+  (source_file)
+  (circuit)
+  (module)
+  (else)
+  (when)
+] @local.scope
+
+; References
+(identifier) @local.reference
+
+; Definitions
+(port
+  (identifier) @local.definition.field)
+
+(wire
+  (identifier) @local.definition.field)
+
+(cmem
+  (identifier) @local.definition.field)
+
+(smem
+  (identifier) @local.definition.field)
+
+(memory
+  (identifier) @local.definition.field)
+
+(register
+  (identifier) @local.definition.field)
+
+(circuit
+  (identifier) @local.definition.namespace)
+
+(module
+  (identifier) @local.definition.namespace)
+
+(parameter
+  (identifier) @local.definition.parameter)
+
+(rdwr
+  (identifier) @local.definition.var)
+
+(node
+  (identifier) @local.definition.var)