feat!: drop modules, general refactor and cleanup

5 files changed, 0 insertions, 160 deletions

diff --git a/queries/vrl/folds.scm b/queries/vrl/folds.scm
deleted file mode 100644
index 6c6d587de..000000000
--- a/queries/vrl/folds.scm
+++ /dev/null
@@ -1,6 +0,0 @@
-[
-  (block)
-  (object)
-  (array)
-  (arguments)
-] @fold
diff --git a/queries/vrl/highlights.scm b/queries/vrl/highlights.scm
deleted file mode 100644
index f74d6dd55..000000000
--- a/queries/vrl/highlights.scm
+++ /dev/null
@@ -1,108 +0,0 @@
-(comment) @comment @spell
-
-(null) @constant.builtin
-
-(timestamp) @constant
-
-(closure_variables
-  (ident) @variable.parameter)
-
-(integer) @number
-
-(float) @number.float
-
-[
-  (string)
-  (raw_string)
-] @string
-
-[
-  (raw_string_escape_sequence)
-  (escape_sequence)
-  (regex_escape_sequence)
-] @string.escape
-
-(string_template
-  "{{" @punctuation.special
-  (_)
-  "}}" @punctuation.special)
-
-(regex) @string.regexp
-
-(boolean) @boolean
-
-(ident) @variable
-
-(noop) @variable.builtin
-
-(function_call
-  (ident) @function.call)
-
-; VRL queries
-(query
-  [
-    (event)
-    (metadata)
-  ] @variable.builtin)
-
-(query
-  (path
-    [
-      (field) @variable
-      (string) @string
-      (index) @number
-      "." @punctuation.delimiter
-    ]))
-
-"return" @keyword.return
-
-"abort" @keyword.exception
-
-[
-  "if"
-  "else"
-] @keyword.conditional
-
-[
-  "="
-  "=="
-  "!="
-  "|="
-  ">"
-  ">="
-  "<"
-  "<="
-  "+"
-  "-"
-  "*"
-  "/"
-  "&&"
-  "||"
-  "??"
-  "|"
-  "!"
-] @operator
-
-[
-  "->"
-  ":"
-  ";"
-  ","
-] @punctuation.delimiter
-
-[
-  "("
-  ")"
-  "["
-  "]"
-  "{"
-  "}"
-] @punctuation.bracket
-
-(closure_variables
-  "|" @punctuation.bracket)
-
-(function_call
-  (ident) @keyword.exception
-  "!"
-  (#any-of? @keyword.exception "assert" "assert_eq"))
diff --git a/queries/vrl/indents.scm b/queries/vrl/indents.scm
deleted file mode 100644
index 1fc1249e0..000000000
--- a/queries/vrl/indents.scm
+++ /dev/null
@@ -1,24 +0,0 @@
-[
-  (block)
-  (object)
-  (array)
-  (arguments)
-] @indent.begin
-
-(block
-  "}" @indent.end)
-
-(object
-  "}" @indent.end)
-
-(array
-  "]" @indent.end)
-
-(arguments
-  ")" @indent.end)
-
-[
-  ")"
-  "]"
-  "}"
-] @indent.branch
diff --git a/queries/vrl/injections.scm b/queries/vrl/injections.scm
deleted file mode 100644
index 5aaf9bcd2..000000000
--- a/queries/vrl/injections.scm
+++ /dev/null
@@ -1,6 +0,0 @@
-((comment) @injection.content
-  (#set! injection.language "comment"))
-
-((regex) @injection.content
-  (#offset! @injection.content 0 2 0 -1)
-  (#set! injection.language "regex"))
diff --git a/queries/vrl/locals.scm b/queries/vrl/locals.scm
deleted file mode 100644
index 786da98c5..000000000
--- a/queries/vrl/locals.scm
+++ /dev/null
@@ -1,16 +0,0 @@
-(closure_variables
-  (ident) @local.definition.parameter)
-
-[
-  (ident)
-  (metadata)
-] @local.reference
-
-(query
-  (event) @local.reference)
-
-[
-  (block)
-  (closure)
-  (if_statement)
-] @local.scope