feat!: drop modules, general refactor and cleanup

5 files changed, 0 insertions, 255 deletions

diff --git a/queries/typescript/folds.scm b/queries/typescript/folds.scm
deleted file mode 100644
index df0b8942a..000000000
--- a/queries/typescript/folds.scm
+++ /dev/null
@@ -1,8 +0,0 @@
-; inherits: ecma
-
-[
-  (interface_declaration)
-  (internal_module)
-  (type_alias_declaration)
-  (enum_declaration)
-] @fold
diff --git a/queries/typescript/highlights.scm b/queries/typescript/highlights.scm
deleted file mode 100644
index 2fb13d800..000000000
--- a/queries/typescript/highlights.scm
+++ /dev/null
@@ -1,208 +0,0 @@
-; inherits: ecma
-
-"require" @keyword.import
-
-(import_require_clause
-  source: (string) @string.special.url)
-
-[
-  "declare"
-  "implements"
-  "type"
-  "override"
-  "module"
-  "asserts"
-  "infer"
-  "is"
-  "using"
-] @keyword
-
-[
-  "namespace"
-  "interface"
-  "enum"
-] @keyword.type
-
-[
-  "keyof"
-  "satisfies"
-] @keyword.operator
-
-(as_expression
-  "as" @keyword.operator)
-
-(mapped_type_clause
-  "as" @keyword.operator)
-
-[
-  "abstract"
-  "private"
-  "protected"
-  "public"
-  "readonly"
-] @keyword.modifier
-
-; types
-(type_identifier) @type
-
-(predefined_type) @type.builtin
-
-(import_statement
-  "type"
-  (import_clause
-    (named_imports
-      (import_specifier
-        name: (identifier) @type))))
-
-(template_literal_type) @string
-
-(non_null_expression
-  "!" @operator)
-
-; punctuation
-(type_arguments
-  [
-    "<"
-    ">"
-  ] @punctuation.bracket)
-
-(type_parameters
-  [
-    "<"
-    ">"
-  ] @punctuation.bracket)
-
-(object_type
-  [
-    "{|"
-    "|}"
-  ] @punctuation.bracket)
-
-(union_type
-  "|" @punctuation.delimiter)
-
-(intersection_type
-  "&" @punctuation.delimiter)
-
-(type_annotation
-  ":" @punctuation.delimiter)
-
-(type_predicate_annotation
-  ":" @punctuation.delimiter)
-
-(index_signature
-  ":" @punctuation.delimiter)
-
-(omitting_type_annotation
-  "-?:" @punctuation.delimiter)
-
-(adding_type_annotation
-  "+?:" @punctuation.delimiter)
-
-(opting_type_annotation
-  "?:" @punctuation.delimiter)
-
-"?." @punctuation.delimiter
-
-(abstract_method_signature
-  "?" @punctuation.special)
-
-(method_signature
-  "?" @punctuation.special)
-
-(method_definition
-  "?" @punctuation.special)
-
-(property_signature
-  "?" @punctuation.special)
-
-(optional_parameter
-  "?" @punctuation.special)
-
-(optional_type
-  "?" @punctuation.special)
-
-(public_field_definition
-  [
-    "?"
-    "!"
-  ] @punctuation.special)
-
-(flow_maybe_type
-  "?" @punctuation.special)
-
-(template_type
-  [
-    "${"
-    "}"
-  ] @punctuation.special)
-
-(conditional_type
-  [
-    "?"
-    ":"
-  ] @keyword.conditional.ternary)
-
-; Parameters
-(required_parameter
-  pattern: (identifier) @variable.parameter)
-
-(optional_parameter
-  pattern: (identifier) @variable.parameter)
-
-(required_parameter
-  (rest_pattern
-    (identifier) @variable.parameter))
-
-; ({ a }) => null
-(required_parameter
-  (object_pattern
-    (shorthand_property_identifier_pattern) @variable.parameter))
-
-; ({ a = b }) => null
-(required_parameter
-  (object_pattern
-    (object_assignment_pattern
-      (shorthand_property_identifier_pattern) @variable.parameter)))
-
-; ({ a: b }) => null
-(required_parameter
-  (object_pattern
-    (pair_pattern
-      value: (identifier) @variable.parameter)))
-
-; ([ a ]) => null
-(required_parameter
-  (array_pattern
-    (identifier) @variable.parameter))
-
-; a => null
-(arrow_function
-  parameter: (identifier) @variable.parameter)
-
-; global declaration
-(ambient_declaration
-  "global" @module)
-
-; function signatures
-(ambient_declaration
-  (function_signature
-    name: (identifier) @function))
-
-; method signatures
-(method_signature
-  name: (_) @function.method)
-
-(abstract_method_signature
-  name: (property_identifier) @function.method)
-
-; property signatures
-(property_signature
-  name: (property_identifier) @function.method
-  type: (type_annotation
-    [
-      (union_type
-        (parenthesized_type
-          (function_type)))
-      (function_type)
-    ]))
diff --git a/queries/typescript/indents.scm b/queries/typescript/indents.scm
deleted file mode 100644
index 9a269ba75..000000000
--- a/queries/typescript/indents.scm
+++ /dev/null
@@ -1,7 +0,0 @@
-; inherits: ecma
-
-[
-  (enum_declaration)
-  (interface_declaration)
-  (object_type)
-] @indent.begin
diff --git a/queries/typescript/injections.scm b/queries/typescript/injections.scm
deleted file mode 100644
index 04328f099..000000000
--- a/queries/typescript/injections.scm
+++ /dev/null
@@ -1 +0,0 @@
-; inherits: ecma
diff --git a/queries/typescript/locals.scm b/queries/typescript/locals.scm
deleted file mode 100644
index b89d9a0c0..000000000
--- a/queries/typescript/locals.scm
+++ /dev/null
@@ -1,31 +0,0 @@
-; inherits: ecma
-
-(required_parameter
-  (identifier) @local.definition)
-
-(optional_parameter
-  (identifier) @local.definition)
-
-; x => x
-(arrow_function
-  parameter: (identifier) @local.definition.parameter)
-
-; ({ a }) => null
-(required_parameter
-  (object_pattern
-    (shorthand_property_identifier_pattern) @local.definition.parameter))
-
-; ({ a: b }) => null
-(required_parameter
-  (object_pattern
-    (pair_pattern
-      value: (identifier) @local.definition.parameter)))
-
-; ([ a ]) => null
-(required_parameter
-  (array_pattern
-    (identifier) @local.definition.parameter))
-
-(required_parameter
-  (rest_pattern
-    (identifier) @local.definition.parameter))