feat!: drop modules, general refactor and cleanup

5 files changed, 0 insertions, 148 deletions

diff --git a/queries/ssh_config/folds.scm b/queries/ssh_config/folds.scm
deleted file mode 100644
index 659835657..000000000
--- a/queries/ssh_config/folds.scm
+++ /dev/null
@@ -1,4 +0,0 @@
-[
-  (host_declaration)
-  (match_declaration)
-] @fold
diff --git a/queries/ssh_config/highlights.scm b/queries/ssh_config/highlights.scm
deleted file mode 100644
index b58360b69..000000000
--- a/queries/ssh_config/highlights.scm
+++ /dev/null
@@ -1,108 +0,0 @@
-; Literals
-(string) @string
-
-(pattern) @string.regexp
-
-(token) @character
-
-[
-  (number)
-  (bytes)
-  (time)
-] @number
-
-[
-  (kex)
-  (mac)
-  (cipher)
-  (key_sig)
-] @variable.parameter
-
-[
-  ; generic
-  "yes"
-  "no"
-  "ask"
-  "auto"
-  "none"
-  "any"
-  ; CanonicalizeHostname
-  "always"
-  ; ControlMaster
-  "autoask"
-  ; FingerprintHash
-  "md5"
-  "sha256"
-  ; PubkeyAuthentication
-  "unbound"
-  "host-bound"
-  ; RequestTTY
-  "force"
-  ; SessionType
-  "subsystem"
-  "default"
-  ; StrictHostKeyChecking
-  "accept-new"
-  "off"
-  ; Tunnel
-  "point-to-point"
-  "ethernet"
-  (ipqos)
-  (verbosity)
-  (facility)
-  (authentication)
-] @constant.builtin
-
-(uri) @string.special.url
-
-; Keywords
-[
-  "Host"
-  "Match"
-] @keyword
-
-(parameter
-  keyword: _ @keyword)
-
-(host_declaration
-  argument: _ @module)
-
-(match_declaration
-  (condition
-    criteria: _ @attribute))
-
-"all" @attribute
-
-; Misc
-[
-  "SSH_AUTH_SOCK"
-  (variable)
-] @constant
-
-(comment) @comment @spell
-
-; Punctuation
-[
-  "${"
-  "}"
-] @punctuation.special
-
-[
-  "\""
-  ","
-  ":"
-  "@"
-] @punctuation.delimiter
-
-[
-  "="
-  "!"
-  "+"
-  "-"
-  "^"
-] @operator
-
-[
-  "*"
-  "?"
-] @character.special
diff --git a/queries/ssh_config/indents.scm b/queries/ssh_config/indents.scm
deleted file mode 100644
index 760707f17..000000000
--- a/queries/ssh_config/indents.scm
+++ /dev/null
@@ -1,12 +0,0 @@
-[
-  (host_declaration)
-  (match_declaration)
-] @indent.begin
-
-; incomplete declarations
-(ERROR
-  .
-  [
-    "Host"
-    "Match"
-  ]) @indent.begin
diff --git a/queries/ssh_config/injections.scm b/queries/ssh_config/injections.scm
deleted file mode 100644
index d1b24be61..000000000
--- a/queries/ssh_config/injections.scm
+++ /dev/null
@@ -1,17 +0,0 @@
-((comment) @injection.content
-  (#set! injection.language "comment"))
-
-((condition
-  criteria: "exec"
-  argument: (string) @injection.content)
-  (#set! injection.language "bash"))
-
-((parameter
-  keyword: [
-    "KnownHostsCommand"
-    "LocalCommand"
-    "RemoteCommand"
-    "ProxyCommand"
-  ]
-  argument: (string) @injection.content)
-  (#set! injection.language "bash"))
diff --git a/queries/ssh_config/locals.scm b/queries/ssh_config/locals.scm
deleted file mode 100644
index a3309a9a6..000000000
--- a/queries/ssh_config/locals.scm
+++ /dev/null
@@ -1,7 +0,0 @@
-(parameter
-  keyword: "Tag"
-  argument: (string) @local.reference)
-
-(condition
-  criteria: "tagged"
-  argument: (pattern) @local.definition)