feat!: drop modules, general refactor and cleanup

5 files changed, 0 insertions, 379 deletions

diff --git a/queries/cpp/folds.scm b/queries/cpp/folds.scm
deleted file mode 100644
index f5f566480..000000000
--- a/queries/cpp/folds.scm
+++ /dev/null
@@ -1,14 +0,0 @@
-; inherits: c
-
-[
-  (for_range_loop)
-  (class_specifier)
-  (field_declaration
-    type: (enum_specifier)
-    default_value: (initializer_list))
-  (template_declaration)
-  (namespace_definition)
-  (try_statement)
-  (catch_clause)
-  (lambda_expression)
-] @fold
diff --git a/queries/cpp/highlights.scm b/queries/cpp/highlights.scm
deleted file mode 100644
index 85ff2dc40..000000000
--- a/queries/cpp/highlights.scm
+++ /dev/null
@@ -1,268 +0,0 @@
-; inherits: c
-
-((identifier) @variable.member
-  (#lua-match? @variable.member "^m_.*$"))
-
-(parameter_declaration
-  declarator: (reference_declarator) @variable.parameter)
-
-; function(Foo ...foo)
-(variadic_parameter_declaration
-  declarator: (variadic_declarator
-    (_) @variable.parameter))
-
-; int foo = 0
-(optional_parameter_declaration
-  declarator: (_) @variable.parameter)
-
-;(field_expression) @variable.parameter ;; How to highlight this?
-((field_expression
-  (field_identifier) @function.method) @_parent
-  (#has-parent? @_parent template_method function_declarator))
-
-(field_declaration
-  (field_identifier) @variable.member)
-
-(field_initializer
-  (field_identifier) @property)
-
-(function_declarator
-  declarator: (field_identifier) @function.method)
-
-(concept_definition
-  name: (identifier) @type.definition)
-
-(alias_declaration
-  name: (type_identifier) @type.definition)
-
-(auto) @type.builtin
-
-(namespace_identifier) @module
-
-((namespace_identifier) @type
-  (#lua-match? @type "^[%u]"))
-
-(case_statement
-  value: (qualified_identifier
-    (identifier) @constant))
-
-(using_declaration
-  .
-  "using"
-  .
-  "namespace"
-  .
-  [
-    (qualified_identifier)
-    (identifier)
-  ] @module)
-
-(destructor_name
-  (identifier) @function.method)
-
-; functions
-(function_declarator
-  (qualified_identifier
-    (identifier) @function))
-
-(function_declarator
-  (qualified_identifier
-    (qualified_identifier
-      (identifier) @function)))
-
-(function_declarator
-  (qualified_identifier
-    (qualified_identifier
-      (qualified_identifier
-        (identifier) @function))))
-
-((qualified_identifier
-  (qualified_identifier
-    (qualified_identifier
-      (qualified_identifier
-        (identifier) @function)))) @_parent
-  (#has-ancestor? @_parent function_declarator))
-
-(function_declarator
-  (template_function
-    (identifier) @function))
-
-(operator_name) @function
-
-"operator" @function
-
-"static_assert" @function.builtin
-
-(call_expression
-  (qualified_identifier
-    (identifier) @function.call))
-
-(call_expression
-  (qualified_identifier
-    (qualified_identifier
-      (identifier) @function.call)))
-
-(call_expression
-  (qualified_identifier
-    (qualified_identifier
-      (qualified_identifier
-        (identifier) @function.call))))
-
-((qualified_identifier
-  (qualified_identifier
-    (qualified_identifier
-      (qualified_identifier
-        (identifier) @function.call)))) @_parent
-  (#has-ancestor? @_parent call_expression))
-
-(call_expression
-  (template_function
-    (identifier) @function.call))
-
-(call_expression
-  (qualified_identifier
-    (template_function
-      (identifier) @function.call)))
-
-(call_expression
-  (qualified_identifier
-    (qualified_identifier
-      (template_function
-        (identifier) @function.call))))
-
-(call_expression
-  (qualified_identifier
-    (qualified_identifier
-      (qualified_identifier
-        (template_function
-          (identifier) @function.call)))))
-
-((qualified_identifier
-  (qualified_identifier
-    (qualified_identifier
-      (qualified_identifier
-        (template_function
-          (identifier) @function.call))))) @_parent
-  (#has-ancestor? @_parent call_expression))
-
-; methods
-(function_declarator
-  (template_method
-    (field_identifier) @function.method))
-
-(call_expression
-  (field_expression
-    (field_identifier) @function.method.call))
-
-; constructors
-((function_declarator
-  (qualified_identifier
-    (identifier) @constructor))
-  (#lua-match? @constructor "^%u"))
-
-((call_expression
-  function: (identifier) @constructor)
-  (#lua-match? @constructor "^%u"))
-
-((call_expression
-  function: (qualified_identifier
-    name: (identifier) @constructor))
-  (#lua-match? @constructor "^%u"))
-
-((call_expression
-  function: (field_expression
-    field: (field_identifier) @constructor))
-  (#lua-match? @constructor "^%u"))
-
-; constructing a type in an initializer list: Constructor ():  **SuperType (1)**
-((field_initializer
-  (field_identifier) @constructor
-  (argument_list))
-  (#lua-match? @constructor "^%u"))
-
-; Constants
-(this) @variable.builtin
-
-(null
-  "nullptr" @constant.builtin)
-
-(true) @boolean
-
-(false) @boolean
-
-; Literals
-(raw_string_literal) @string
-
-; Keywords
-[
-  "try"
-  "catch"
-  "noexcept"
-  "throw"
-] @keyword.exception
-
-[
-  "decltype"
-  "explicit"
-  "friend"
-  "override"
-  "using"
-  "requires"
-  "constexpr"
-] @keyword
-
-[
-  "class"
-  "namespace"
-  "template"
-  "typename"
-  "concept"
-] @keyword.type
-
-[
-  "co_await"
-  "co_yield"
-  "co_return"
-] @keyword.coroutine
-
-[
-  "public"
-  "private"
-  "protected"
-  "final"
-  "virtual"
-] @keyword.modifier
-
-[
-  "new"
-  "delete"
-  "xor"
-  "bitand"
-  "bitor"
-  "compl"
-  "not"
-  "xor_eq"
-  "and_eq"
-  "or_eq"
-  "not_eq"
-  "and"
-  "or"
-] @keyword.operator
-
-"<=>" @operator
-
-"::" @punctuation.delimiter
-
-(template_argument_list
-  [
-    "<"
-    ">"
-  ] @punctuation.bracket)
-
-(template_parameter_list
-  [
-    "<"
-    ">"
-  ] @punctuation.bracket)
-
-(literal_suffix) @operator
diff --git a/queries/cpp/indents.scm b/queries/cpp/indents.scm
deleted file mode 100644
index 0782d226e..000000000
--- a/queries/cpp/indents.scm
+++ /dev/null
@@ -1,8 +0,0 @@
-; inherits: c
-
-(condition_clause) @indent.begin
-
-((field_initializer_list) @indent.begin
-  (#set! indent.start_at_same_line 1))
-
-(access_specifier) @indent.branch
diff --git a/queries/cpp/injections.scm b/queries/cpp/injections.scm
deleted file mode 100644
index 07f21dd14..000000000
--- a/queries/cpp/injections.scm
+++ /dev/null
@@ -1,11 +0,0 @@
-; inherits: c
-((comment) @injection.content
-  (#set! injection.language "comment"))
-
-((comment) @injection.content
-  (#lua-match? @injection.content "/[*\/][!*\/]<?[^a-zA-Z]")
-  (#set! injection.language "doxygen"))
-
-(raw_string_literal
-  delimiter: (raw_string_delimiter) @injection.language
-  (raw_string_content) @injection.content)
diff --git a/queries/cpp/locals.scm b/queries/cpp/locals.scm
deleted file mode 100644
index b24ada85f..000000000
--- a/queries/cpp/locals.scm
+++ /dev/null
@@ -1,78 +0,0 @@
-; inherits: c
-
-; Parameters
-(variadic_parameter_declaration
-  declarator: (variadic_declarator
-    (identifier) @local.definition.parameter))
-
-(optional_parameter_declaration
-  declarator: (identifier) @local.definition.parameter)
-
-; Class / struct definitions
-(class_specifier) @local.scope
-
-(reference_declarator
-  (identifier) @local.definition.var)
-
-(variadic_declarator
-  (identifier) @local.definition.var)
-
-(struct_specifier
-  name: (qualified_identifier
-    name: (type_identifier) @local.definition.type))
-
-(class_specifier
-  name: (type_identifier) @local.definition.type)
-
-(concept_definition
-  name: (identifier) @local.definition.type)
-
-(class_specifier
-  name: (qualified_identifier
-    name: (type_identifier) @local.definition.type))
-
-(alias_declaration
-  name: (type_identifier) @local.definition.type)
-
-;template <typename T>
-(type_parameter_declaration
-  (type_identifier) @local.definition.type)
-
-(template_declaration) @local.scope
-
-; Namespaces
-(namespace_definition
-  name: (namespace_identifier) @local.definition.namespace
-  body: (_) @local.scope)
-
-(namespace_definition
-  name: (nested_namespace_specifier) @local.definition.namespace
-  body: (_) @local.scope)
-
-((namespace_identifier) @local.reference
-  (#set! reference.kind "namespace"))
-
-; Function definitions
-(template_function
-  name: (identifier) @local.definition.function) @local.scope
-
-(template_method
-  name: (field_identifier) @local.definition.method) @local.scope
-
-(function_declarator
-  declarator: (qualified_identifier
-    name: (identifier) @local.definition.function)) @local.scope
-
-(field_declaration
-  declarator: (function_declarator
-    (field_identifier) @local.definition.method))
-
-(lambda_expression) @local.scope
-
-; Control structures
-(try_statement
-  body: (_) @local.scope)
-
-(catch_clause) @local.scope
-
-(requires_expression) @local.scope