feat!: drop modules, general refactor and cleanup

5 files changed, 0 insertions, 294 deletions

diff --git a/queries/capnp/folds.scm b/queries/capnp/folds.scm
deleted file mode 100644
index 6e3f9c187..000000000
--- a/queries/capnp/folds.scm
+++ /dev/null
@@ -1,14 +0,0 @@
-[
-  (annotation_targets)
-  (const_list)
-  (enum)
-  (interface)
-  (implicit_generics)
-  (generics)
-  (group)
-  (method_parameters)
-  (named_return_types)
-  (struct)
-  (struct_shorthand)
-  (union)
-] @fold
diff --git a/queries/capnp/highlights.scm b/queries/capnp/highlights.scm
deleted file mode 100644
index a48c007ed..000000000
--- a/queries/capnp/highlights.scm
+++ /dev/null
@@ -1,141 +0,0 @@
-; Preproc
-[
-  (unique_id)
-  (top_level_annotation_body)
-] @keyword.directive
-
-; Includes
-[
-  "import"
-  "$import"
-  "embed"
-  "using"
-] @keyword.import
-
-(import_path) @string.special.path
-
-; Keywords
-"extends" @keyword
-
-[
-  "struct"
-  "interface"
-  "union"
-  "enum"
-  "annotation"
-  "group"
-  "namespace"
-] @keyword.type
-
-; Builtins
-"const" @keyword.modifier
-
-[
-  (primitive_type)
-  "List"
-] @type.builtin
-
-; Typedefs
-(type_definition) @type.definition
-
-; Labels (@number, @number!)
-(field_version) @label
-
-; Methods
-[
-  (annotation_definition_identifier)
-  (method_identifier)
-] @function.method
-
-; Fields
-(field_identifier) @variable.member
-
-; Properties
-(property) @property
-
-; Parameters
-[
-  (param_identifier)
-  (return_identifier)
-] @variable.parameter
-
-(annotation_target) @variable.parameter.builtin
-
-; Constants
-[
-  (const_identifier)
-  (local_const)
-  (enum_member)
-] @constant
-
-(void) @constant.builtin
-
-; Types
-[
-  (enum_identifier)
-  (extend_type)
-  (type_identifier)
-] @type
-
-; Attributes
-[
-  (annotation_identifier)
-  (attribute)
-] @attribute
-
-; Operators
-"=" @operator
-
-; Literals
-[
-  (string)
-  (concatenated_string)
-  (block_text)
-  (namespace)
-] @string
-
-(namespace) @string.special
-
-(escape_sequence) @string.escape
-
-(data_string) @string.special
-
-(number) @number
-
-(float) @number.float
-
-(boolean) @boolean
-
-(data_hex) @string.special.symbol
-
-; Punctuation
-[
-  "*"
-  "$"
-  ":"
-] @punctuation.special
-
-[
-  "{"
-  "}"
-] @punctuation.bracket
-
-[
-  "("
-  ")"
-] @punctuation.bracket
-
-[
-  "["
-  "]"
-] @punctuation.bracket
-
-[
-  "."
-  ","
-  ";"
-  "->"
-] @punctuation.delimiter
-
-; Comments
-(comment) @comment @spell
diff --git a/queries/capnp/indents.scm b/queries/capnp/indents.scm
deleted file mode 100644
index cc2f4d756..000000000
--- a/queries/capnp/indents.scm
+++ /dev/null
@@ -1,40 +0,0 @@
-[
-  (annotation_targets)
-  (const)
-  (enum)
-  (interface)
-  (implicit_generics)
-  (generics)
-  (group)
-  (method_parameters)
-  (named_return_types)
-  (struct)
-  (union)
-  (field)
-] @indent.begin
-
-((struct_shorthand
-  (property)) @indent.align
-  (#set! indent.open_delimiter "(")
-  (#set! indent.close_delimiter ")"))
-
-((method
-  (field_version)) @indent.align
-  (#set! indent.open_delimiter field_version))
-
-((const_list
-  (const_value)) @indent.align
-  (#set! indent.open_delimiter "[")
-  (#set! indent.close_delimiter "]"))
-
-(concatenated_string) @indent.align
-
-[
-  "}"
-  ")"
-] @indent.end @indent.branch
-
-[
-  (ERROR)
-  (comment)
-] @indent.auto
diff --git a/queries/capnp/injections.scm b/queries/capnp/injections.scm
deleted file mode 100644
index 2f0e58eb6..000000000
--- a/queries/capnp/injections.scm
+++ /dev/null
@@ -1,2 +0,0 @@
-((comment) @injection.content
-  (#set! injection.language "comment"))
diff --git a/queries/capnp/locals.scm b/queries/capnp/locals.scm
deleted file mode 100644
index d1f0ccacc..000000000
--- a/queries/capnp/locals.scm
+++ /dev/null
@@ -1,97 +0,0 @@
-[
-  (message)
-  (annotation_targets)
-  (const_list)
-  (enum)
-  (interface)
-  (implicit_generics)
-  (generics)
-  (group)
-  (method_parameters)
-  (named_return_types)
-  (struct)
-  (struct_shorthand)
-  (union)
-] @local.scope
-
-[
-  (extend_type)
-  (field_type)
-] @local.reference
-
-(custom_type
-  (type_identifier) @local.reference)
-
-(custom_type
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.reference)))
-
-(annotation_definition_identifier) @local.definition
-
-(const_identifier) @local.definition.constant
-
-(enum
-  (enum_identifier) @local.definition.enum)
-
-[
-  (enum_member)
-  (field_identifier)
-] @local.definition.field
-
-(method_identifier) @local.definition.method
-
-(namespace) @local.definition.namespace
-
-[
-  (param_identifier)
-  (return_identifier)
-] @local.definition.parameter
-
-(group
-  (type_identifier) @local.definition.type)
-
-(struct
-  (type_identifier) @local.definition.type)
-
-(union
-  (type_identifier) @local.definition.type)
-
-(interface
-  (type_identifier) @local.definition.type)
-
-; Generics Related (don't know how to combine these)
-(struct
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.definition.parameter)))
-
-(interface
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.definition.parameter)))
-
-(method
-  (implicit_generics
-    (implicit_generic_parameters
-      (generic_identifier) @local.definition.parameter)))
-
-(method
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.definition.parameter)))
-
-(annotation
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.definition.type)))
-
-(replace_using
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.definition.type)))
-
-(return_type
-  (generics
-    (generic_parameters
-      (generic_identifier) @local.definition.type)))