feat!: drop modules, general refactor and cleanup

5 files changed, 0 insertions, 358 deletions

diff --git a/queries/bicep/folds.scm b/queries/bicep/folds.scm
deleted file mode 100644
index 217a86d6a..000000000
--- a/queries/bicep/folds.scm
+++ /dev/null
@@ -1,19 +0,0 @@
-[
-  (module_declaration)
-  (metadata_declaration)
-  (output_declaration)
-  (parameter_declaration)
-  (resource_declaration)
-  (type_declaration)
-  (variable_declaration)
-  (parenthesized_expression)
-  (decorators)
-  (array)
-  (object)
-  (if_statement)
-  (for_statement)
-  (subscript_expression)
-  (ternary_expression)
-  (string)
-  (comment)
-] @fold
diff --git a/queries/bicep/highlights.scm b/queries/bicep/highlights.scm
deleted file mode 100644
index 35c9d6c17..000000000
--- a/queries/bicep/highlights.scm
+++ /dev/null
@@ -1,234 +0,0 @@
-; Includes
-[
-  "import"
-  "provider"
-  "with"
-  "as"
-  "from"
-] @keyword.import
-
-; Namespaces
-(module_declaration
-  (identifier) @module)
-
-; Builtins
-(primitive_type) @type.builtin
-
-((member_expression
-  object: (identifier) @type.builtin)
-  (#eq? @type.builtin "sys"))
-
-; Functions
-(call_expression
-  function: (identifier) @function.call)
-
-(user_defined_function
-  name: (identifier) @function)
-
-; Properties
-(object_property
-  (identifier) @property
-  ":" @punctuation.delimiter
-  (_))
-
-(object_property
-  (compatible_identifier) @property
-  ":" @punctuation.delimiter
-  (_))
-
-(property_identifier) @property
-
-; Attributes
-(decorator
-  "@" @attribute)
-
-(decorator
-  (call_expression
-    (identifier) @attribute))
-
-(decorator
-  (call_expression
-    (member_expression
-      object: (identifier) @attribute
-      property: (property_identifier) @attribute)))
-
-; Types
-(type_declaration
-  (identifier) @type)
-
-(type_declaration
-  (identifier)
-  "="
-  (identifier) @type)
-
-(type
-  (identifier) @type)
-
-(resource_declaration
-  (identifier) @type)
-
-(resource_expression
-  (identifier) @type)
-
-; Parameters
-(parameter_declaration
-  (identifier) @variable.parameter
-  (_))
-
-(call_expression
-  function: (_)
-  (arguments
-    (identifier) @variable.parameter))
-
-(call_expression
-  function: (_)
-  (arguments
-    (member_expression
-      object: (identifier) @variable.parameter)))
-
-(parameter
-  .
-  (identifier) @variable.parameter)
-
-; Variables
-(variable_declaration
-  (identifier) @variable
-  (_))
-
-(metadata_declaration
-  (identifier) @variable
-  (_))
-
-(output_declaration
-  (identifier) @variable
-  (_))
-
-(object_property
-  (_)
-  ":"
-  (identifier) @variable)
-
-(for_statement
-  "for"
-  (for_loop_parameters
-    (loop_variable) @variable
-    (loop_enumerator) @variable))
-
-; Conditionals
-"if" @keyword.conditional
-
-(ternary_expression
-  "?" @keyword.conditional.ternary
-  ":" @keyword.conditional.ternary)
-
-; Loops
-(for_statement
-  "for" @keyword.repeat
-  "in"
-  ":" @punctuation.delimiter)
-
-; Keywords
-[
-  "module"
-  "metadata"
-  "output"
-  "param"
-  "resource"
-  "existing"
-  "targetScope"
-  "type"
-  "var"
-  "using"
-  "test"
-] @keyword
-
-"func" @keyword.function
-
-"assert" @keyword.exception
-
-; Operators
-[
-  "+"
-  "-"
-  "*"
-  "/"
-  "%"
-  "||"
-  "&&"
-  "|"
-  "=="
-  "!="
-  "=~"
-  "!~"
-  ">"
-  ">="
-  "<="
-  "<"
-  "??"
-  "="
-  "!"
-  ".?"
-] @operator
-
-(subscript_expression
-  "?" @operator)
-
-(nullable_type
-  "?" @operator)
-
-"in" @keyword.operator
-
-; Literals
-(string) @string
-
-(escape_sequence) @string.escape
-
-(number) @number
-
-(boolean) @boolean
-
-(null) @constant.builtin
-
-; Misc
-(compatible_identifier
-  "?" @punctuation.special)
-
-(nullable_return_type) @punctuation.special
-
-[
-  "{"
-  "}"
-] @punctuation.bracket
-
-[
-  "["
-  "]"
-] @punctuation.bracket
-
-[
-  "("
-  ")"
-] @punctuation.bracket
-
-[
-  "."
-  ":"
-  "::"
-  "=>"
-] @punctuation.delimiter
-
-; Interpolation
-(interpolation) @none
-
-(interpolation
-  "${" @punctuation.special
-  "}" @punctuation.special)
-
-(interpolation
-  (identifier) @variable)
-
-; Comments
-[
-  (comment)
-  (diagnostic_comment)
-] @comment @spell
diff --git a/queries/bicep/indents.scm b/queries/bicep/indents.scm
deleted file mode 100644
index 055e51b23..000000000
--- a/queries/bicep/indents.scm
+++ /dev/null
@@ -1,27 +0,0 @@
-[
-  (array)
-  (object)
-] @indent.begin
-
-"}" @indent.end
-
-[
-  "{"
-  "}"
-] @indent.branch
-
-[
-  "["
-  "]"
-] @indent.branch
-
-[
-  "("
-  ")"
-] @indent.branch
-
-[
-  (ERROR)
-  (comment)
-  (diagnostic_comment)
-] @indent.auto
diff --git a/queries/bicep/injections.scm b/queries/bicep/injections.scm
deleted file mode 100644
index 5c2d4a57b..000000000
--- a/queries/bicep/injections.scm
+++ /dev/null
@@ -1,5 +0,0 @@
-([
-  (comment)
-  (diagnostic_comment)
-] @injection.content
-  (#set! injection.language "comment"))
diff --git a/queries/bicep/locals.scm b/queries/bicep/locals.scm
deleted file mode 100644
index cc9c3c2cf..000000000
--- a/queries/bicep/locals.scm
+++ /dev/null
@@ -1,73 +0,0 @@
-; Scopes
-[
-  (infrastructure)
-  (call_expression)
-  (lambda_expression)
-  (subscript_expression)
-  (if_statement)
-  (for_statement)
-  (array)
-  (object)
-  (interpolation)
-] @local.scope
-
-; References
-(property_identifier) @local.reference
-
-(call_expression
-  (identifier) @local.reference)
-
-(object_property
-  (_)
-  ":"
-  (identifier) @local.reference)
-
-(resource_expression
-  (identifier) @local.reference)
-
-; Definitions
-(type) @local.definition.associated
-
-(object_property
-  (identifier) @local.definition.field
-  (_))
-
-(object_property
-  (compatible_identifier) @local.definition.field
-  (_))
-
-(user_defined_function
-  name: (identifier) @local.definition.function)
-
-(module_declaration
-  (identifier) @local.definition.namespace)
-
-(parameter_declaration
-  (identifier) @local.definition.parameter
-  (_))
-
-(parameter
-  .
-  (identifier) @local.definition.parameter)
-
-(type_declaration
-  (identifier) @local.definition.type
-  (_))
-
-(variable_declaration
-  (identifier) @local.definition.var
-  (_))
-
-(metadata_declaration
-  (identifier) @local.definition.var
-  (_))
-
-(output_declaration
-  (identifier) @local.definition.var
-  (_))
-
-(for_statement
-  "for"
-  (for_loop_parameters
-    (loop_variable) @local.definition.var
-    (loop_enumerator) @local.definition.var))