import dchroot, dlocate, dpkg-cross, madison, piuparts, toolchain-source,

bzr, cplay, date, quilt, urvt from HEAD

4 files changed, 91 insertions, 0 deletions

diff --git a/Completion/Unix/Command/_bzr b/Completion/Unix/Command/_bzr
new file mode 100644
index 000000000..26e992dd3
--- /dev/null
+++ b/Completion/Unix/Command/_bzr
@@ -0,0 +1,13 @@
+#compdef bzr
+
+local _bzr_subcommands expl curcontext="$curcontext"
+
+_bzr_subcommands=(${(f)"$(_call_program bzr bzr shell-complete)"})
+
+if (( CURRENT == 2 )); then
+  _describe -t subcommand 'subcommand' _bzr_subcommands
+else
+# this part should call bzr shell-complete <subcmd> when
+# it has been tweaked properly
+  _files
+fi
diff --git a/Completion/Unix/Command/_cplay b/Completion/Unix/Command/_cplay
new file mode 100644
index 000000000..24b159425
--- /dev/null
+++ b/Completion/Unix/Command/_cplay
@@ -0,0 +1,8 @@
+#compdef cplay
+
+_arguments -s \
+  '-n[enable restricted mode]' \
+  '-r[toggle playlist repeat mode]' \
+  '-R[toggle playlist random mode]' \
+  '-v[toggle PCM and MASTER volume control]' \
+  '*:playlist or directory or audio file:_files'
diff --git a/Completion/Unix/Command/_date b/Completion/Unix/Command/_date
new file mode 100644
index 000000000..8b1b389aa
--- /dev/null
+++ b/Completion/Unix/Command/_date
@@ -0,0 +1,48 @@
+#compdef date
+
+if _pick_variant -r is_gnu gnu="Free Software Foundation" unix --version; then
+  _arguments \
+    '-d[date]:time string:' \
+    '-f[file]:date file:_files' \
+    '-I[iso-8601]:time spec:' \
+    '-r[reference]:file:_files' \
+    '-R[rfc-2822]' \
+    '-s[set]:time string:' \
+    '-u[utc]' \
+    -- \
+    '*=FILE*:file:_files' \
+    '*=DATEFILE*:date file:_files' \
+    ':format or date:'
+else
+  case "$OSTYPE" in
+	  (solaris*)
+	  _arguments \
+	    '-u[utc]' \
+	    '-a:adjustment:' \
+            ':format or date:'
+	  ;;
+	  (freebsd*)
+	  _arguments \
+	    '-u[utc]' \
+	    '-n[only set time on current machine]' \
+	    '-d:daylight savingg time value:' \
+	    '-j[do not try to set date]' \
+	    '-f:parsing format:' \
+	    '-r:seconds since epoch:' \
+	    '-t:minutes west of GMT:' \
+	    '-v:adjustment value:' \
+            ':format or date:'
+	  ;;
+	  (openbsd*)
+	  _arguments \
+	    '-u[utc]' \
+	    '-n[only set time on current machine]' \
+	    '-d:daylight savingg time value:' \
+	    '-a[gradually skew]' \
+	    '-r:seconds since epoch:' \
+	    '-t:minutes west of GMT:' \
+            ':format or date:'
+	  ;;
+  esac
+fi
+
diff --git a/Completion/Unix/Command/_quilt b/Completion/Unix/Command/_quilt
new file mode 100644
index 000000000..cbb1d90df
--- /dev/null
+++ b/Completion/Unix/Command/_quilt
@@ -0,0 +1,22 @@
+#compdef quilt
+
+local _quilt_subcommands expl curcontext="$curcontext"
+
+_arguments \
+  '--trace' \
+  '--quiltrc:config file:_files' \
+  '--version' \
+  '*::quilt command:->subcmd' && return 0
+
+
+ _quilt_subcommands=(add files import previous setup annotate fold mail
+ push snapshot applied fork new refresh top delete graph next remove
+ unapplied diff grep patches rename upgrade edit header pop series)
+
+
+if (( CURRENT == 1 )); then
+  _describe -t subcommand 'subcommand' _quilt_subcommands
+else
+  # this part should be tailored for subcmds
+  _files
+fi