moved from Completion/User/_cvs

1 files changed, 952 insertions, 0 deletions

diff --git a/Completion/Unix/Command/_cvs b/Completion/Unix/Command/_cvs
new file mode 100644
index 000000000..8235c8d37
--- /dev/null
+++ b/Completion/Unix/Command/_cvs
@@ -0,0 +1,952 @@
+#compdef cvs
+
+# redefine _cvs.
+
+_cvs () {
+  # "+Qqrwtnlvb:T:e:d:Hfz:s:xa"
+  _arguments -s \
+    '-a[authenticate]' \
+    '-f[disable .cvsrc]' \
+    '(-n)-l[disable logging]' \
+    '(-l)-n[no change]' \
+    '(-q)-Q[really quiet]' \
+    '(-Q)-q[somewhat quiet]' \
+    '(-w)-r[make new working file read only]' \
+    '-t[trace]' \
+    '(-r)-w[make new working file read-write]' \
+    '-x[encrypt client/server communication]' \
+    '(--version)-v[print version]' \
+    '(-v)--version[print version]' \
+    '(   --help --help-commands --help-synonyms --help-options)-H[print help]' \
+    '(-H        --help-commands --help-synonyms --help-options)--help[print help]' \
+    '(-H --help                 --help-synonyms --help-options)--help-commands[command help]' \
+    '(-H --help --help-commands                 --help-options)--help-synonyms[command synonyms help]' \
+    '(-H --help --help-commands --help-synonyms               )--help-options[global options help]' \
+    '*--allow-root=[allowable root for pserver]:rootdir:_files -/' \
+    '-b+[binary directory]:bindir:_cvs_bindir' \
+    '-T+[temporary directory]:temporary directory:_cvs_tempdir' \
+    '-d+[cvs root directory]:cvsroot:_cvs_root' \
+    '-e+[editor]:editor:_cvs_editor' \
+    '-s+[user variable]:user variable:_cvs_user_variable' \
+    '-z+[gzip level]:gzip level:_cvs_gzip_level' \
+    '*::cvs command:_cvs_command'
+}
+
+# define cvs command dispatch function.
+
+(( $+functions[_cvs_command] )) ||
+_cvs_command () {
+  local cmd cvsroot="$CVSROOT"
+  [[ -f CVS/Root ]] && cvsroot="$(<CVS/Root)"
+  [[ -n "$opt_args[-d]" ]] && cvsroot=${(e)~opt_args[-d]:Q}
+
+  if (( ! $+_cvs_cmds )); then
+    typeset -gA _cvs_cmds
+    _cvs_cmds=(
+      ${(f)${(F)${${(M)${(f)"$(_call_program commands cvs --help-commands 2>&1)"}:# *}/(#b) #([a-z]##) */$match[1]
+ }}}
+      ${(f)${(F)${${(M)${(f)"$(_call_program synonyms cvs --help-synonyms 2>&1)"}:# *}/(#b) #([a-z]#)   #([a-z]#) ([a-z]#)/$match[1]
+ $match[2] $match[3] }}}