blob: 3e3b9da3e61b7401e1b4b357554ff62eecbd1dc2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
; Scopes
[
(script)
(class_declaration)
(enum_declaration)
(function_declaration)
(attribute_declaration)
(array)
(block)
(table)
(anonymous_function)
(parenthesized_expression)
(if_statement)
(else_statement)
(while_statement)
(do_while_statement)
(switch_statement)
(for_statement)
(foreach_statement)
(try_statement)
(catch_statement)
] @local.scope
; References
[
(identifier)
(global_variable)
] @local.reference
; Definitions
(const_declaration
. (identifier) @local.definition.constant)
(enum_declaration
. (identifier) @local.definition.enum)
(member_declaration
(identifier) @local.definition.field
. "=")
(table_slot
. (identifier) @local.definition.field
. ["=" ":"])
((function_declaration
. (identifier) @local.definition.function)
(#not-has-ancestor? @local.definition.function member_declaration))
(member_declaration
(function_declaration
. (identifier) @local.definition.method))
(class_declaration
. (identifier) @local.definition.type)
(var_statement
"var" . (identifier) @local.definition.variable)
(local_declaration
(identifier) @local.definition.variable
. "=")
|
