feat!: drop modules, general refactor and cleanup

5 files changed, 152 insertions, 0 deletions

diff --git a/runtime/queries/kconfig/folds.scm b/runtime/queries/kconfig/folds.scm
new file mode 100644
index 000000000..980667dfc
--- /dev/null
+++ b/runtime/queries/kconfig/folds.scm
@@ -0,0 +1,9 @@
+[
+  (config)
+  (menuconfig)
+  (choice)
+  (comment_entry)
+  (menu)
+  (if)
+  (help_text)
+] @fold
diff --git a/runtime/queries/kconfig/highlights.scm b/runtime/queries/kconfig/highlights.scm
new file mode 100644
index 000000000..deb88bc00
--- /dev/null
+++ b/runtime/queries/kconfig/highlights.scm
@@ -0,0 +1,105 @@
+"source" @keyword.import
+
+[
+  "mainmenu"
+  "config"
+  "menuconfig"
+  "choice"
+  "endchoice"
+  "comment"
+  "menu"
+  "endmenu"
+  "prompt"
+  "default"
+  "range"
+  "help"
+  (optional)
+  (modules)
+] @keyword
+
+[
+  "if"
+  "endif"
+  "depends on"
+  "select"
+  "imply"
+  "visible if"
+] @keyword.conditional
+
+[
+  "def_bool"
+  "def_tristate"
+] @keyword.function
+
+[
+  "||"
+  "&&"
+  "="
+  "!="
+  "<"
+  ">"
+  "<="
+  ">="
+  "!"
+  ":="
+  "+="
+  "?="
+] @operator
+
+[
+  "bool"
+  "tristate"
+  "int"
+  "hex"
+  "string"
+] @type.builtin
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+"," @punctuation.delimiter
+
+(macro_variable
+  [
+    "$("
+    ")"
+  ] @punctuation.special)
+
+(symbol) @variable
+
+[
+  (string)
+  (macro_content)
+  (text)
+] @string
+
+(config
+  name: (name
+    (symbol) @constant))
+
+(menuconfig
+  name: (name
+    (symbol) @constant))
+
+(choice
+  name: (name
+    (symbol) @constant))
+
+((symbol) @constant
+  (#lua-match? @constant "[A-Z0-9]+"))
+
+(mainmenu
+  name: (string) @markup.heading)
+
+(comment_entry
+  name: (string) @markup.heading)
+
+(menu
+  name: (string) @markup.heading)
+
+(source
+  (string) @string.special.url)
+
+(comment) @comment @spell
diff --git a/runtime/queries/kconfig/indents.scm b/runtime/queries/kconfig/indents.scm
new file mode 100644
index 000000000..faa83602f
--- /dev/null
+++ b/runtime/queries/kconfig/indents.scm
@@ -0,0 +1,12 @@
+(help_text
+  (text) @indent.auto)
+
+[
+  (config)
+  (menuconfig)
+  (choice)
+  (comment_entry)
+  (menu)
+  (if)
+  (help_text)
+] @indent.begin
diff --git a/runtime/queries/kconfig/injections.scm b/runtime/queries/kconfig/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/kconfig/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/kconfig/locals.scm b/runtime/queries/kconfig/locals.scm
new file mode 100644
index 000000000..09a50fecb
--- /dev/null
+++ b/runtime/queries/kconfig/locals.scm
@@ -0,0 +1,24 @@
+[
+  (symbol)
+  (string)
+] @local.reference
+
+[
+  (config)
+  (menuconfig)
+  (choice)
+  (comment_entry)
+  (menu)
+  (if)
+] @local.scope
+
+(type_definition
+  (string) @local.definition.var)
+
+(type_definition
+  (input_prompt
+    (string) @local.definition.var))
+
+(type_definition_default
+  (expression
+    (string) @local.definition.var))