From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/vrl/folds.scm      |   6 +++
 runtime/queries/vrl/highlights.scm | 108 +++++++++++++++++++++++++++++++++++++
 runtime/queries/vrl/indents.scm    |  24 +++++++++
 runtime/queries/vrl/injections.scm |   6 +++
 runtime/queries/vrl/locals.scm     |  16 ++++++
 5 files changed, 160 insertions(+)
 create mode 100644 runtime/queries/vrl/folds.scm
 create mode 100644 runtime/queries/vrl/highlights.scm
 create mode 100644 runtime/queries/vrl/indents.scm
 create mode 100644 runtime/queries/vrl/injections.scm
 create mode 100644 runtime/queries/vrl/locals.scm

(limited to 'runtime/queries/vrl')

diff --git a/runtime/queries/vrl/folds.scm b/runtime/queries/vrl/folds.scm
new file mode 100644
index 000000000..6c6d587de
--- /dev/null
+++ b/runtime/queries/vrl/folds.scm
@@ -0,0 +1,6 @@
+[
+  (block)
+  (object)
+  (array)
+  (arguments)
+] @fold
diff --git a/runtime/queries/vrl/highlights.scm b/runtime/queries/vrl/highlights.scm
new file mode 100644
index 000000000..f74d6dd55
--- /dev/null
+++ b/runtime/queries/vrl/highlights.scm
@@ -0,0 +1,108 @@
+(comment) @comment @spell
+
+(null) @constant.builtin
+
+(timestamp) @constant
+
+(closure_variables
+  (ident) @variable.parameter)
+
+(integer) @number
+
+(float) @number.float
+
+[
+  (string)
+  (raw_string)
+] @string
+
+[
+  (raw_string_escape_sequence)
+  (escape_sequence)
+  (regex_escape_sequence)
+] @string.escape
+
+(string_template
+  "{{" @punctuation.special
+  (_)
+  "}}" @punctuation.special)
+
+(regex) @string.regexp
+
+(boolean) @boolean
+
+(ident) @variable
+
+(noop) @variable.builtin
+
+(function_call
+  (ident) @function.call)
+
+; VRL queries
+(query
+  [
+    (event)
+    (metadata)
+  ] @variable.builtin)
+
+(query
+  (path
+    [
+      (field) @variable
+      (string) @string
+      (index) @number
+      "." @punctuation.delimiter
+    ]))
+
+"return" @keyword.return
+
+"abort" @keyword.exception
+
+[
+  "if"
+  "else"
+] @keyword.conditional
+
+[
+  "="
+  "=="
+  "!="
+  "|="
+  ">"
+  ">="
+  "<"
+  "<="
+  "+"
+  "-"
+  "*"
+  "/"
+  "&&"
+  "||"
+  "??"
+  "|"
+  "!"
+] @operator
+
+[
+  "->"
+  ":"
+  ";"
+  ","
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(closure_variables
+  "|" @punctuation.bracket)
+
+(function_call
+  (ident) @keyword.exception
+  "!"
+  (#any-of? @keyword.exception "assert" "assert_eq"))
diff --git a/runtime/queries/vrl/indents.scm b/runtime/queries/vrl/indents.scm
new file mode 100644
index 000000000..1fc1249e0
--- /dev/null
+++ b/runtime/queries/vrl/indents.scm
@@ -0,0 +1,24 @@
+[
+  (block)
+  (object)
+  (array)
+  (arguments)
+] @indent.begin
+
+(block
+  "}" @indent.end)
+
+(object
+  "}" @indent.end)
+
+(array
+  "]" @indent.end)
+
+(arguments
+  ")" @indent.end)
+
+[
+  ")"
+  "]"
+  "}"
+] @indent.branch
diff --git a/runtime/queries/vrl/injections.scm b/runtime/queries/vrl/injections.scm
new file mode 100644
index 000000000..5aaf9bcd2
--- /dev/null
+++ b/runtime/queries/vrl/injections.scm
@@ -0,0 +1,6 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((regex) @injection.content
+  (#offset! @injection.content 0 2 0 -1)
+  (#set! injection.language "regex"))
diff --git a/runtime/queries/vrl/locals.scm b/runtime/queries/vrl/locals.scm
new file mode 100644
index 000000000..786da98c5
--- /dev/null
+++ b/runtime/queries/vrl/locals.scm
@@ -0,0 +1,16 @@
+(closure_variables
+  (ident) @local.definition.parameter)
+
+[
+  (ident)
+  (metadata)
+] @local.reference
+
+(query
+  (event) @local.reference)
+
+[
+  (block)
+  (closure)
+  (if_statement)
+] @local.scope
-- 
cgit v1.2.3-70-g09d2