From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/vimdoc/highlights.scm | 74 +++++++++++++++++++++++++++++++++++
 runtime/queries/vimdoc/injections.scm |  4 ++
 2 files changed, 78 insertions(+)
 create mode 100644 runtime/queries/vimdoc/highlights.scm
 create mode 100644 runtime/queries/vimdoc/injections.scm

(limited to 'runtime/queries/vimdoc')

diff --git a/runtime/queries/vimdoc/highlights.scm b/runtime/queries/vimdoc/highlights.scm
new file mode 100644
index 000000000..829a643ae
--- /dev/null
+++ b/runtime/queries/vimdoc/highlights.scm
@@ -0,0 +1,74 @@
+(h1
+  (delimiter) @markup.heading.1
+  (heading) @markup.heading.1)
+
+(h2
+  (delimiter) @markup.heading.2
+  (heading) @markup.heading.2)
+
+(h3
+  (heading) @markup.heading.3)
+
+(column_heading
+  (heading) @markup.heading.4)
+
+(column_heading
+  (delimiter) @markup.heading.4
+  (#set! conceal ""))
+
+(tag
+  "*" @label
+  (#set! conceal ""))
+
+(tag
+  text: (_) @label)
+
+(taglink
+  "|" @markup.link
+  (#set! conceal ""))
+
+(taglink
+  text: (_) @markup.link)
+
+(optionlink
+  text: (_) @markup.link)
+
+(codespan
+  "`" @markup.raw
+  (#set! conceal ""))
+
+(codespan
+  text: (_) @markup.raw)
+
+((codeblock) @markup.raw.block
+  (#set! priority 90))
+
+(codeblock
+  ">" @markup.raw
+  (#set! conceal ""))
+
+(codeblock
+  (language) @label
+  (#set! conceal ""))
+
+(block
+  "<" @markup.raw
+  (#set! conceal ""))
+
+(argument) @variable.parameter
+
+(keycode) @string.special
+
+((url) @string.special.url
+  (#set! @string.special.url url @string.special.url))
+
+(modeline) @keyword.directive
+
+((note) @comment.note
+  (#any-of? @comment.note "Note:" "NOTE:" "Notes:"))
+
+((note) @comment.warning
+  (#any-of? @comment.warning "Warning:" "WARNING:"))
+
+((note) @comment.error
+  (#any-of? @comment.error "Deprecated:" "DEPRECATED:"))
diff --git a/runtime/queries/vimdoc/injections.scm b/runtime/queries/vimdoc/injections.scm
new file mode 100644
index 000000000..3b8fbf0f3
--- /dev/null
+++ b/runtime/queries/vimdoc/injections.scm
@@ -0,0 +1,4 @@
+((codeblock
+  (language) @injection.language
+  (code) @injection.content)
+  (#set! injection.include-children))
-- 
cgit v1.3.1