From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/udev/highlights.scm | 67 +++++++++++++++++++++++++++++++++++++
 runtime/queries/udev/injections.scm | 14 ++++++++
 runtime/queries/udev/locals.scm     | 29 ++++++++++++++++
 3 files changed, 110 insertions(+)
 create mode 100644 runtime/queries/udev/highlights.scm
 create mode 100644 runtime/queries/udev/injections.scm
 create mode 100644 runtime/queries/udev/locals.scm

(limited to 'runtime/queries/udev')

diff --git a/runtime/queries/udev/highlights.scm b/runtime/queries/udev/highlights.scm
new file mode 100644
index 000000000..f95238d70
--- /dev/null
+++ b/runtime/queries/udev/highlights.scm
@@ -0,0 +1,67 @@
+(match
+  key: _ @keyword)
+
+(assignment
+  key: _ @property)
+
+(value) @string
+
+; NOTE: higher priorities override bash highlights
+((fmt_sub
+  .
+  _ @character.special)
+  (#set! priority 101))
+
+((var_sub
+  .
+  _ @variable.builtin)
+  (#set! priority 101))
+
+[
+  (system_const)
+  (run_type)
+  (import_type)
+  (kernel_param)
+  (seclabel)
+] @attribute
+
+((attribute) @attribute
+  (#set! priority 101))
+
+((env_var) @constant
+  (#set! priority 101))
+
+((pattern) @string.special
+  (#set! priority 101))
+
+([
+  "\\\""
+  (c_escape)
+] @string.escape
+  (#set! priority 101))
+
+(octal) @number
+
+((number) @number
+  (#set! priority 101))
+
+[
+  (match_op)
+  (assignment_op)
+] @operator
+
+("+" @punctuation.special
+  (#set! priority 101))
+
+([
+  "{"
+  "}"
+] @punctuation.bracket
+  (#set! priority 101))
+
+[
+  ","
+  (linebreak)
+] @punctuation.delimiter
+
+(comment) @comment @spell
diff --git a/runtime/queries/udev/injections.scm b/runtime/queries/udev/injections.scm
new file mode 100644
index 000000000..1718349c6
--- /dev/null
+++ b/runtime/queries/udev/injections.scm
@@ -0,0 +1,14 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((match
+  key: "PROGRAM"
+  (value
+    (content) @injection.content))
+  (#set! injection.language "bash"))
+
+((assignment
+  key: "RUN"
+  (value
+    (content) @injection.content))
+  (#set! injection.language "bash"))
diff --git a/runtime/queries/udev/locals.scm b/runtime/queries/udev/locals.scm
new file mode 100644
index 000000000..e1a2f65d2
--- /dev/null
+++ b/runtime/queries/udev/locals.scm
@@ -0,0 +1,29 @@
+; labels
+(assignment
+  key: "LABEL"
+  (value
+    (content) @local.definition))
+
+(assignment
+  key: "GOTO"
+  (value
+    (content) @local.reference))
+
+; env vars
+(assignment
+  key: "ENV"
+  (env_var) @local.definition.var)
+
+(match
+  key: "ENV"
+  (env_var) @local.reference)
+
+(var_sub
+  (env_var) @local.reference)
+
+; misc
+[
+  (attribute)
+  (kernel_param)
+  (seclabel)
+] @local.reference
-- 
cgit v1.2.3-70-g09d2