From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/surface/folds.scm      |  6 +++++
 runtime/queries/surface/highlights.scm | 44 ++++++++++++++++++++++++++++++++++
 runtime/queries/surface/indents.scm    | 14 +++++++++++
 runtime/queries/surface/injections.scm | 10 ++++++++
 4 files changed, 74 insertions(+)
 create mode 100644 runtime/queries/surface/folds.scm
 create mode 100644 runtime/queries/surface/highlights.scm
 create mode 100644 runtime/queries/surface/indents.scm
 create mode 100644 runtime/queries/surface/injections.scm

(limited to 'runtime/queries/surface')

diff --git a/runtime/queries/surface/folds.scm b/runtime/queries/surface/folds.scm
new file mode 100644
index 000000000..994f12e1e
--- /dev/null
+++ b/runtime/queries/surface/folds.scm
@@ -0,0 +1,6 @@
+; Surface folds similar to HTML and includes blocks
+[
+  (tag)
+  (component)
+  (block)
+] @fold
diff --git a/runtime/queries/surface/highlights.scm b/runtime/queries/surface/highlights.scm
new file mode 100644
index 000000000..b874b8c1d
--- /dev/null
+++ b/runtime/queries/surface/highlights.scm
@@ -0,0 +1,44 @@
+; Surface text is not highlighted
+(text) @none
+
+; Surface has two types of comments, both are highlighted as such
+(comment) @comment @spell
+
+; Surface attributes are highlighted as HTML attributes
+(attribute_name) @tag.attribute
+
+; Attributes are highlighted as strings
+(quoted_attribute_value) @string
+
+; Surface blocks are highlighted as keywords
+[
+  (start_block)
+  (end_block)
+  (subblock)
+] @keyword
+
+; Surface supports HTML tags and are highlighted as such
+[
+  "<"
+  ">"
+  "</"
+  "/>"
+  "{"
+  "}"
+  "<!--"
+  "-->"
+  "{!--"
+  "--}"
+] @tag.delimiter
+
+; Surface tags are highlighted as HTML
+(tag_name) @tag
+
+; Surface components are highlighted as types (Elixir modules)
+(component_name) @type
+
+; Surface directives are highlighted as keywords
+(directive_name) @keyword
+
+; Surface operators
+"=" @operator
diff --git a/runtime/queries/surface/indents.scm b/runtime/queries/surface/indents.scm
new file mode 100644
index 000000000..1df9fe6fd
--- /dev/null
+++ b/runtime/queries/surface/indents.scm
@@ -0,0 +1,14 @@
+; Surface indents like HTML, with the addition of blocks
+[
+  (component)
+  (tag)
+  (block)
+] @indent.begin
+
+; Dedent at the end of each tag, as well as a subblock
+[
+  (end_tag)
+  (end_component)
+  (end_block)
+  (subblock)
+] @indent.branch
diff --git a/runtime/queries/surface/injections.scm b/runtime/queries/surface/injections.scm
new file mode 100644
index 000000000..72cab5e80
--- /dev/null
+++ b/runtime/queries/surface/injections.scm
@@ -0,0 +1,10 @@
+; Surface expressions and components are Elixir code
+([
+  (expression_value)
+  (component_name)
+] @injection.content
+  (#set! injection.language "elixir"))
+
+; Surface comments are nvim-treesitter comments
+((comment) @injection.content
+  (#set! injection.language "comment"))
-- 
cgit v1.2.3-70-g09d2