From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/properties/highlights.scm | 50 +++++++++++++++++++++++++++++++
 runtime/queries/properties/injections.scm |  2 ++
 runtime/queries/properties/locals.scm     |  5 ++++
 3 files changed, 57 insertions(+)
 create mode 100644 runtime/queries/properties/highlights.scm
 create mode 100644 runtime/queries/properties/injections.scm
 create mode 100644 runtime/queries/properties/locals.scm

(limited to 'runtime/queries/properties')

diff --git a/runtime/queries/properties/highlights.scm b/runtime/queries/properties/highlights.scm
new file mode 100644
index 000000000..b9390be8c
--- /dev/null
+++ b/runtime/queries/properties/highlights.scm
@@ -0,0 +1,50 @@
+(comment) @comment @spell
+
+(key) @property
+
+(value) @string
+
+(value
+  (escape) @string.escape)
+
+((value) @boolean
+  (#any-of? @boolean "true" "false"))
+
+((value) @number
+  (#lua-match? @number "^%d+$"))
+
+((index) @number
+  (#lua-match? @number "^%d+$"))
+
+((substitution
+  (key) @constant)
+  (#lua-match? @constant "^[A-Z_][A-Z0-9_]*$"))
+
+(substitution
+  (key) @function
+  "::" @punctuation.special
+  (secret) @constant.macro)
+
+(property
+  [
+    "="
+    ":"
+  ] @operator)
+
+[
+  "${"
+  "}"
+] @punctuation.special
+
+(substitution
+  ":" @punctuation.special)
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  "."
+  "\\"
+] @punctuation.delimiter
diff --git a/runtime/queries/properties/injections.scm b/runtime/queries/properties/injections.scm
new file mode 100644
index 000000000..2f0e58eb6
--- /dev/null
+++ b/runtime/queries/properties/injections.scm
@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
diff --git a/runtime/queries/properties/locals.scm b/runtime/queries/properties/locals.scm
new file mode 100644
index 000000000..91a3b9a86
--- /dev/null
+++ b/runtime/queries/properties/locals.scm
@@ -0,0 +1,5 @@
+(property
+  (key) @local.definition)
+
+(substitution
+  (key) @local.reference)
-- 
cgit v1.2.3-70-g09d2