From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/glimmer_javascript/highlights.scm | 61 +++++++++++++++++++++++
 runtime/queries/glimmer_javascript/indents.scm    |  5 ++
 runtime/queries/glimmer_javascript/injections.scm |  7 +++
 runtime/queries/glimmer_javascript/locals.scm     |  1 +
 4 files changed, 74 insertions(+)
 create mode 100644 runtime/queries/glimmer_javascript/highlights.scm
 create mode 100644 runtime/queries/glimmer_javascript/indents.scm
 create mode 100644 runtime/queries/glimmer_javascript/injections.scm
 create mode 100644 runtime/queries/glimmer_javascript/locals.scm

(limited to 'runtime/queries/glimmer_javascript')

diff --git a/runtime/queries/glimmer_javascript/highlights.scm b/runtime/queries/glimmer_javascript/highlights.scm
new file mode 100644
index 000000000..5bec5b149
--- /dev/null
+++ b/runtime/queries/glimmer_javascript/highlights.scm
@@ -0,0 +1,61 @@
+; inherits: ecma
+
+(glimmer_opening_tag) @tag.builtin
+
+(glimmer_closing_tag) @tag.builtin
+
+; Copied from javascript
+; Parameters
+(formal_parameters
+  (identifier) @variable.parameter)
+
+(formal_parameters
+  (rest_pattern
+    (identifier) @variable.parameter))
+
+; ({ a }) => null
+(formal_parameters
+  (object_pattern
+    (shorthand_property_identifier_pattern) @variable.parameter))
+
+; ({ a = b }) => null
+(formal_parameters
+  (object_pattern
+    (object_assignment_pattern
+      (shorthand_property_identifier_pattern) @variable.parameter)))
+
+; ({ a: b }) => null
+(formal_parameters
+  (object_pattern
+    (pair_pattern
+      value: (identifier) @variable.parameter)))
+
+; ([ a ]) => null
+(formal_parameters
+  (array_pattern
+    (identifier) @variable.parameter))
+
+; ({ a } = { a }) => null
+(formal_parameters
+  (assignment_pattern
+    (object_pattern
+      (shorthand_property_identifier_pattern) @variable.parameter)))
+
+; ({ a = b } = { a }) => null
+(formal_parameters
+  (assignment_pattern
+    (object_pattern
+      (object_assignment_pattern
+        (shorthand_property_identifier_pattern) @variable.parameter))))
+
+; a => null
+(arrow_function
+  parameter: (identifier) @variable.parameter)
+
+; optional parameters
+(formal_parameters
+  (assignment_pattern
+    left: (identifier) @variable.parameter))
+
+; punctuation
+(optional_chain) @punctuation.delimiter
diff --git a/runtime/queries/glimmer_javascript/indents.scm b/runtime/queries/glimmer_javascript/indents.scm
new file mode 100644
index 000000000..2bf2b7801
--- /dev/null
+++ b/runtime/queries/glimmer_javascript/indents.scm
@@ -0,0 +1,5 @@
+; inherits: ecma
+
+(glimmer_opening_tag) @indent.begin
+
+(glimmer_closing_tag) @indent.end
diff --git a/runtime/queries/glimmer_javascript/injections.scm b/runtime/queries/glimmer_javascript/injections.scm
new file mode 100644
index 000000000..174372a48
--- /dev/null
+++ b/runtime/queries/glimmer_javascript/injections.scm
@@ -0,0 +1,7 @@
+; inherits: ecma
+
+; Ember Unified <template> syntax
+; e.g.: <template><SomeComponent @arg={{double @value}} /></template>
+((glimmer_template) @injection.content
+  (#set! injection.language "glimmer")
+  (#set! injection.include-children))
diff --git a/runtime/queries/glimmer_javascript/locals.scm b/runtime/queries/glimmer_javascript/locals.scm
new file mode 100644
index 000000000..04328f099
--- /dev/null
+++ b/runtime/queries/glimmer_javascript/locals.scm
@@ -0,0 +1 @@
+; inherits: ecma
-- 
cgit v1.2.3-70-g09d2