From 692b051b09935653befdb8f7ba8afdb640adf17b Mon Sep 17 00:00:00 2001
From: Christian Clason <c.clason@uni-graz.at>
Date: Mon, 12 Jun 2023 09:54:30 -0600
Subject: feat!: drop modules, general refactor and cleanup

---
 runtime/queries/git_config/folds.scm      |  2 +
 runtime/queries/git_config/highlights.scm | 59 ++++++++++++++++++++++++++
 runtime/queries/git_config/injections.scm | 69 +++++++++++++++++++++++++++++++
 3 files changed, 130 insertions(+)
 create mode 100644 runtime/queries/git_config/folds.scm
 create mode 100644 runtime/queries/git_config/highlights.scm
 create mode 100644 runtime/queries/git_config/injections.scm

(limited to 'runtime/queries/git_config')

diff --git a/runtime/queries/git_config/folds.scm b/runtime/queries/git_config/folds.scm
new file mode 100644
index 000000000..cb376d5b5
--- /dev/null
+++ b/runtime/queries/git_config/folds.scm
@@ -0,0 +1,2 @@
+((section) @fold
+  (#trim! @fold))
diff --git a/runtime/queries/git_config/highlights.scm b/runtime/queries/git_config/highlights.scm
new file mode 100644
index 000000000..6b37e9090
--- /dev/null
+++ b/runtime/queries/git_config/highlights.scm
@@ -0,0 +1,59 @@
+; Sections
+(section_name) @markup.heading
+
+((section_name) @keyword.import
+  (#eq? @keyword.import "include"))
+
+((section_header
+  (section_name) @keyword.import
+  (subsection_name))
+  (#eq? @keyword.import "includeIf"))
+
+(variable
+  (name) @property)
+
+; Operators
+"=" @operator
+
+; Literals
+(integer) @number
+
+[
+  (true)
+  (false)
+] @boolean
+
+(string) @string
+
+(escape_sequence) @string.escape
+
+((string) @string.special.path
+  (#lua-match? @string.special.path "^[.]?[.]?[/]"))
+
+((string) @string.special.path
+  (#lua-match? @string.special.path "^[~]"))
+
+(section_header
+  [
+    "\""
+    (subsection_name)
+  ] @string.special)
+
+((section_header
+  (section_name) @_name
+  (subsection_name) @string.special.url)
+  (#any-of? @_name "credential" "url"))
+
+((variable
+  (name) @_name
+  value: (string) @string.special.url)
+  (#eq? @_name "insteadOf"))
+
+; Punctuation
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+; Comments
+(comment) @comment @spell
diff --git a/runtime/queries/git_config/injections.scm b/runtime/queries/git_config/injections.scm
new file mode 100644
index 000000000..7bda6979c
--- /dev/null
+++ b/runtime/queries/git_config/injections.scm
@@ -0,0 +1,69 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((variable
+  (name) @_name
+  value: (string) @injection.content)
+  (#any-of? @_name "cmd" "command" "textconv" "sendmailCmd")
+  (#set! injection.language "bash"))
+
+(section
+  (variable
+    (name) @_name
+    value: (string) @injection.content)
+  (#eq? @_name "tool")
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_pager)
+  (variable
+    value: (string) @injection.content)
+  (#eq? @_pager "pager")
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_interactive)
+  (variable
+    (name) @_name
+    value: (string) @injection.content)
+  (#eq? @_interactive "interactive")
+  (#eq? @_name "diffFilter")
+  (#set! injection.language "bash"))
+
+; https://github.com/git-lfs/git-lfs
+; git lfs install
+(section
+  (section_header
+    (section_name) @_filter
+    (subsection_name) @_lfs)
+  (variable
+    (name) @_name
+    value: (string) @injection.content)
+  (#eq? @_filter "filter")
+  (#eq? @_lfs "lfs")
+  (#any-of? @_name "smudge" "process" "clean")
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_alias)
+  (variable
+    value: (string) @injection.content)
+  (#eq? @_alias "alias")
+  (#lua-match? @injection.content "^!")
+  (#offset! @injection.content 0 1 0 0)
+  (#set! injection.language "bash"))
+
+(section
+  (section_header
+    (section_name) @_alias)
+  (variable
+    value: (string
+      "\""
+      "\"") @injection.content)
+  (#eq? @_alias "alias")
+  (#lua-match? @injection.content "^\"!")
+  (#offset! @injection.content 0 2 0 -1)
+  (#set! injection.language "bash"))
-- 
cgit v1.2.3-70-g09d2